поиск и удаление чисел по размеру шрифта в указанном диапазоне

[Aegi]

Доброго времени суток!
Имеется таблица с картинками,описанием и ценами товаров.Проблема в следующем - цены бывают новые и старые,новые имеют размерность шрифта 15, старые выполнены с размерностью 11. Мне необходимо избавиться от старых, сохранив новые.
Поэтому мне необходим макрос проверяющий размерность шрифта в заполненных ячейках столбца С и очищающий ячейки имеющих размерность шрифта цифр равной 11.
Подскажите ещё макрос по поиску ячеек значение которых равно 0 и их очищение.
Заранее благодарен.

[EducatedFool]

Вы бы файл свой прикрепили - макрос был бы уже готов

А то воссоздавать ваш файл для теста макроса дольше, чем писать макрос из 3 строк...

[Aegi]

В загруженном примере надо избавиться от чисел выделенных красным в столбце С.
В столбце Е при автозаполнении кроме нужных значений появляется 0, хочу его удалить, а не скрывать.

[Скрипт]

Aegi, в столбце "E" у вас формулы. Нужно сохранить формулу или прямо можно ноль вместе с формулой удалить?

[Скрипт]

Макрос, который на активном листе, в столбце "C" находит и удаляет текст, который имеет размер 11 пунктов и имеет красный цвет:

Sub Макрос1()

    '1. Ускоряем работу кода.
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    Application.Calculation = xlCalculationManual

    '2. Макрос будет работать на основе команды "Replace".
    'Команда "Replace" связана с окном "Найти и заменить".
        'Чтобы параметры из окна "Найти и заменить" не повлияли
        'на работу кода, очищаем параметры форматирования,
        'связанные с командой "Replace".
    Application.FindFormat.Clear
    
    '2. Устанавливаем параметры для поиска формата текста.
    'Под форматом подразумевается: размер шрифта, цвет шрифта.
    With Application.FindFormat.Font
        .Size = 11
        .Color = 255
    End With
    
    '3. Поиск и замена.
    'Часть кода получена с помощью макрорекордера.
    Columns("C").Replace What:="", Replacement:="", LookAt:=xlPart, _
        SearchOrder:=xlByColumns, MatchCase:=False, SearchFormat:=True, _
        ReplaceFormat:=False
        
    '4. Убираем настройки поиска, чтобы не мешало пользователю
        'работать с окном "Найти и заменить".
    Application.FindFormat.Clear
    
    '5. Включаем то, что отключали.
    Application.ScreenUpdating = True
    Application.EnableEvents = True
    Application.Calculation = xlCalculationAutomatic
    
End Sub

Примечание

Номер цвета шрифта можно вот так узнать:

1. перейдите в программу Excel;
2. сделайте активной ячейку, у которой нужно узнать: какой цвет текста;
3. перейдите в программу VBA;
4. View - Immediate Window. Появится окно;
5. в это окно скопируйте и вставьте этот код и нажмите клавишу "Enter".
6. будет получен номер цвета и этот номер можно подставить в код.
   

   print activecell.Font.Color

[Aegi]

Сообщение от Скрипт

Aegi, в столбце "E" у вас формулы. Нужно сохранить формулу или прямо можно ноль вместе с формулой удалить?

там просто рассчитали, а далее столбец E копируется и вставляется вместо С посредством "вставка значение"
В прикреплённом файле мне нужно уже удалить нули макросом.

[Скрипт]

Макрос, который на активном листе, в столбце "E" удаляет из ячейки данные, если в ячейке ноль. При это, удаляется и формула из ячейки.

Sub Procedure_1()

    Dim myE() As Variant
    Dim myLastRow As Long
    Dim i As Long
    
    '1. Ускоряем работу кода.
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    Application.Calculation = xlCalculationManual

    '2. Определяем последнюю строку с данными, чтобы
        'знать: со скольки данными работать.
    myLastRow = Columns("E").Find(What:="?", LookIn:=xlValues, LookAt:=xlPart, _
        SearchOrder:=xlByColumns, SearchDirection:=xlPrevious, _
        MatchCase:=False, SearchFormat:=False).Row
    
    '3. Берём данные из Excel-листа в VBA-массив.
    'В VBA-массиве быстрее работать, чем с Excel-ячейками.
    myE() = Range("E1:E" & myLastRow).Value
    
    '4. Удаляем ноль и формулу из Excel-листа.
    'С помощью цикла с "i" двигаемся по массиву "myE".
    For i = 1 To UBound(myE, 1) Step 1
        'Если в элементе массива "myE" ноль, то
        'удаляем данные из Excel-ячейки. Порядковые номера
        'элементов массива и строки Excel-листа совпадают в этом коде.
        If myE(i, 1) = 0 Then
            Cells(i, "E").Formula = ""
        End If
    Next i
    
    '5. Включаем то, что отключали.
    Application.ScreenUpdating = True
    Application.EnableEvents = True
    Application.Calculation = xlCalculationAutomatic

End Sub

[Скрипт]

Макрос, который на активном листе, в столбце "E" удаляет из ячейки данные, если в ячейке ноль. Макрос удаляет формулы из всех ячеек в столбце "E", где есть данные.
Этот макрос должен быстрее работать, чем макрос из сообщения #7.

Sub Procedure_1()

    Dim myE() As Variant
    Dim myLastRow As Long
    Dim i As Long
    
    '1. Ускоряем работу кода.
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    Application.Calculation = xlCalculationManual

    '2. Определяем последнюю строку с данными, чтобы
        'знать: со скольки данными работать.
    myLastRow = Columns("E").Find(What:="?", LookIn:=xlValues, LookAt:=xlPart, _
        SearchOrder:=xlByColumns, SearchDirection:=xlPrevious, _
        MatchCase:=False, SearchFormat:=False).Row
    
    '3. Берём данные из Excel-листа в VBA-массив.
    'В VBA-массиве быстрее работать, чем с Excel-ячейками.
    myE() = Range("E1:E" & myLastRow).Value
    
    '4. Удаляем ноль в массиве "myE".
    'С помощью цикла с "i" двигаемся по массиву "myE".
    For i = 1 To UBound(myE, 1) Step 1
        'Если в элементе массива "myE" ноль, то
        'удаляем данные из элемента массива "myE".
        If myE(i, 1) = 0 Then
            myE(i, 1) = Empty
        End If
    Next i
    
    '5. Вставляем изменённые данные на Excel-лист.
    Range("E1:E" & myLastRow).Value = myE()
    
    '6. Включаем то, что отключали.
    Application.ScreenUpdating = True
    Application.EnableEvents = True
    Application.Calculation = xlCalculationAutomatic

End Sub

[Aegi]

Всё работает как и задумано,Огромное спасибо вам Скрипт.