Замена определенного значения на картинку(VBA)

[Евгений Таб]

Прошу помощи!

Дано:

Макрос который вставляет картинку в определенный диапазон с настройкой масштаба IMG.

Вопрос:

Нужно чтобы картинка вставала (точнее ее верхний левый угол) в ячейку в которой имеется текстовое значение, например "Путин", точнее "Путин", а не в определенный диапазон указанный в коде, что бы он искал значение "Путин" и заменял его на IMG.

Спасибо огромное!

PHP код:

Sub q()
    
    Dim shActive As Excel.Worksheet
    Dim myPath As String
    Dim myShape As Excel.Shape
    Dim myPicture As Picture
    Dim myMax As Long
    
    myPath = "C:\321.jpg"
    
    Set shActive = ActiveSheet
    
   
    If shActive.Shapes.Count = 0 Then
    
        myMax = 40
        
   
    Else
    
        For Each myShape In shActive.Shapes
          
            If myShape.TopLeftCell.Column = 12 Then
             
                If myMax = 0 Then
                    myMax = myShape.TopLeftCell.Row
                Else
                   
                    If myShape.TopLeftCell.Row > myMax Then
                    
                        myMax = myShape.TopLeftCell.Row
                    End If
                End If
            End If
            
        Next myShape
    
        If myMax = 0 Then
            myMax = 40
     
        Else
            myMax = myMax + 1
        End If
        
    End If
    
   
    Set myPicture = shActive.Pictures.Insert(myPath)
    
    Set myShape = myPicture.ShapeRange(1)
    
    myShape.LockAspectRatio = msoTrue
    myShape.Width = 250
    
   
    myShape.Top = shActive.Cells(myMax, "A").Top
    myShape.Left = shActive.Cells(myMax, "A").Left
    
End Sub 


[EducatedFool]

Картинку одну надо вставить?
Или картинок много, и их названия содержат текст ячеек, куда их надо поместить?

Если второй вариант, - вам подойдёт эта надстройка для Excel^
http://excelvba.ru/programmes/PastePictures

[Евгений Таб]

Да, картинку одну - простую маленькую, просто вместо определенного значения!
Надстройки тут через чур будут.
Спасибо за быстрый ответ)

[Евгений Таб]

К примеру, поиск на листе ячейки с текстовым значение "Собака" , и он в эту ячейку запиливает этот макрос(вставляет JPG)

[Евгений Таб]

Незнаю как еще обяснить, в общем ничего не менять в макросе, изменить только не конкретное поле для вставки, а конкретное которое макрос будет искать

[Евгений Таб]

Во вложении ДО и ПОСЛЕ работы макроса, поиск Собака

[Евгений Таб]

Никак не могу вставить код поиска по значению((

[EducatedFool]

Sub ВставкаКартинкиВНайденнуюЯчейку()
    Dim myPath$, myShape As Shape, myPicture As Picture, cell As Range, txt$
    txt$ = "Собака"        ' текст для поиска
    myPath$ = "C:\test.jpg"

    Set cell = ActiveSheet.UsedRange.Find(txt$)
    If cell Is Nothing Then
        MsgBox "Ячейка с заданным текстом «" & txt$ & "» не найдена", vbCritical
        Exit Sub
    End If

    Set myPicture = ActiveSheet.Pictures.Insert(myPath)
    myPicture.Top = cell.Top
    myPicture.Left = cell.Left
End Sub

[Евгений Таб]

Очень Вам благодарен!

[Евгений Таб]

Еще один вопрос.
Что нужно дописать в макросе что бы он отправлял сохраненный файл pdf на адрес электронной почты? Клиент lotus ibm.
Но чтобы также сохранялся с условием?
Спасибо!

PHP код:

Sub ач32()
        ChDir "C:\Documents and Settings\ezhutov\Рабочий стол\Экспорт
заявок"
          ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
       ActiveSheet.Range("C2"), Quality:= _
       xlQualityStandard, IncludeDocProperties:=False,
IgnorePrintAreas:=False, _
       OpenAfterPublish:=False

End Sub