Сравнение 2х столбцов, с копипастой ВСЕХ совпавших строк второго столбца на другой лист

[TypucT]

Добрый день. Искал такой код в поисковике - не нашел.
Нужно сравнить два столбца.
в первом уникальные не повторяющиеся коды,
во втором повторяются несколько раз. в третьем разные значения
пример
А В С
один один 111
два один 222
три три 333
четыре четыре 444
пять три 555

нужно сравнить значения в столбцах А В
и скопировать на другой лист все совпадающие строки
пример результата:
А В С
один один 111
один 222
три три 333
три 555
четыре четыре 444

[TypucT]

Есть макрос который просто ищет совпадения и ставит их напротив (типа ВПР)
можно ли его переделать?
Dim a(), b(), c(), t&, x As Byte, iLastrow As Long, i As Long

With Sheets(1)
iLastrow = .Cells(Rows.Count, 1).End(xlUp).Row
a = Range(.[A1], .Range("A" & iLastrow)).Value
iLastrow = .Cells(Rows.Count, 2).End(xlUp).Row
b = Range(.[D1], .Range("B" & iLastrow)).Value

ReDim c(1 To UBound(a), 1 To 3)

With CreateObject("Scripting.Dictionary" )

For i = 1 To UBound(a)
.Item(a(i, 1)) = i
Next

For i = 1 To UBound(b)
If .exists(b(i, 1)) Then
t = .Item(b(i, 1))
For x = 1 To 3: c(t, x) = b(i, x): Next
End If
Next
End With

.[F1].Resize(UBound(c), 3) = c
.Activate
End With

End Sub

[staniiislav]

Так:?

Sub ArrCopy()
Dim a(), t&,  lsRow&, i&

    With Sheets("Лист1")
    
        With .UsedRange
            lsRow = .Row + .Rows.Count - 1
        End With
        
        a = Range("A1:C" & lsRow).Value
        
            With CreateObject("Scripting.Dictionary")
            
                For i = 1 To UBound(a): .Item(a(i, 1)) = i: Next
                
                For i = 1 To UBound(a)
                    If .exists(a(i, 2)) Then
                        t = t + 1
                        a(t, 1) = a(i, 2)
                        a(t, 2) = a(i, 3)
                    End If
                Next
                
            End With
            
    End With
    
    If t Then
        With Sheets("Лист2")
        
            With .UsedRange
                lsRow = .Row + .Rows.Count - 1
            End With
            
            .Range("A1:C" & lsRow).ClearContents
            .Range("A1").Resize(t, 2) = a
            
        End With
    End If
End Sub

[TypucT]

Спасибо, этого достаточно. Вы мне очень помогли.