ассемблер. исправить чтобы число выводящие на экран возводилось не в квадрат, а в куб

[natali121212]

подскажите что нужно исправить чтобы число выводящие на экран возводилось не в квадрат а в куб

str1 DB 13,10,"Vvedite chislo: ","$"
str3 DB 13,10,"Kvadrat chisla: ","$"
num1 DB ?
.code ; начало сегмента кода программы
start:
 mov ax,@data ; инициализация сегмента данных
 mov ds,ax
Вывод заставки
lea dx,str0 ; в DX - адрес строки
mov ah,9
int 21h ; вывод строки
input_1:
; Ввод множимого
lea dx,str1 ; в DX - адрес строки
mov ah,9
int 21h ; вывод строки

mov ah,1
int 21h ; ввод символа
cmp al,'0' ; проверка введенного символа
jl input_1
cmp al,'9'
jg input_1
sub al,30h ; преобразование кода символа в число
mov num1,al ; запомнить множимое
mov al,num1
mul al ; операция умножения
aam ; коррекция результата в ax
mov dl,ah ; в DL старшая цифра
mov dh,al ; в DH младшая цифра
or dh,30h ; получение ASCII-кода младшей цифры
or dl,30h ; получение ASCII-кода старшей цифры
push dx ; сохранить регистр DX в стеке
lea dx,str3 ; в DX - адрес строки
mov ah,9
int 21h ; вывод строки
pop dx ; восстановить регистр DX из стека
mov ah,2 ; вывод на экран старшей цифры
int 21h
xchg dh,dl ; обмен значений в регистрах DH и DL
mov ah,2 ; вывод на экран младшей цифры
int 21h
mov ax,4C00h
int 21h ; завершение программы с кодом 0
END start

________
Код нужно оформлять по правилам:
тегом [CODE]..[/СODE]
(это кнопочка на панели форматирования с решёточкой #)
Не забывайте об этом!

Модератор.

[Serge_Bliznykov]

Натали, а Вы эту программу сами писали?
Ибо, если нет, то Вам очень затруднительно будет разобраться в коде...

впрочем, извольте.
Разбирайтесь:

.MODEL    TINY 
.386 
.data
str0 DB 13,10,"Program written at programmersforum.ru","$"
str1 DB 13,10,"Vvedite chislo: ","$"
str3 DB 13,10,"Kub chisla: ","$"
num1 DB ?
String	db	5 dup (?),' $'  ; Резервируем 5 байт для строки + пробел
StringEnd	=	$-1            ; Указывает на символ '$'
.code ; начало сегмента кода программы
start:
  mov ax,@data ; инициализация сегмента данных
  mov ds,ax
  mov es, ax      ; настройка ES на DS
  ; Вывод заставки
  lea dx,str0 ; в DX - адрес строки
  mov ah,9
  int 21h ; вывод строки
  input_1:
  ; Ввод множимого
  lea dx,str1 ; в DX - адрес строки
  mov ah,9
  int 21h ; вывод строки

  mov ah,1
  int 21h ; ввод символа
  cmp al,'0' ; проверка введенного символа
  jl input_1
  cmp al,'9'
  jg input_1
  sub al,30h ; преобразование кода символа в число
  mov num1,al ; запомнить множимое
  mov al,num1
  mul Num1 ; операция умножения
;  aam ; коррекция результата в ax
  mul Num1 ; операция умножения
;  aam ; коррекция результата в ax
  push ax

  lea dx,str3 ; в DX - адрес строки
  mov ah,9
  int 21h ; вывод строки

  pop ax
  call PrintAx


  mov ax,4C00h
  int 21h ; завершение программы с кодом 0

; ПОДПРОГРАММЫ
;------------------------------------------------------------------------------------
; Напечатать значение регистра AX в его десятичное представление (в виде строки)
;   на входе AX, 
;------------------------------------------------------------------------------------
PrintAx:        push    bx
                push    cx
		std                    ; Устанавливаем ОБРАТНЫЙ порядок записи
		lea	di,StringEnd-2 ; ES:DI = последний символ строки String (не учитывая $ и пробел)

; Начинаем перевод числа AX в строку
		mov	cx,10          ; Задаемся делителем CX = 10
Repeat:
		xor	dx,dx          ; Обнуляем DX (для деления)
		div	cx             ; Делим DX:AX на CX (10),
                                       ; Получаем в AX частное, в DX остаток
		xchg	ax,dx          ; Меняем их местами (нас интересует остаток)
		add	al,'0'         ; Получаем в AL символ десятичной цифры
		stosb                  ; И записываем ее в строку
		xchg	ax,dx          ; Восстанавливаем AX (частное)
		or	ax,ax          ; Сравниваем AX с 0
		jne	Repeat         ; Если не ноль, то повторяем

; Теперь осталось вывести строку на экран
		mov	ah,9
		lea	dx,[di+1]      ; Заносим в DX адрес начала строки
		int	21h            ; Выводим ее на экран
		pop     cx
		pop     bx
		ret

END start