Замена точки запятой сразу при вводе значения в ячейку листа

[ольгаг]

Здравствуйте Уважаемые программисты!
Подскажите пожалуйста, как кодом vba excel 2003 при вводе в ячейку точки (в любой раскладке) автоматически заменять ее на запятую?
Заранее спасибо!

[Казанский]

Смысл в том, чтобы вводить числа? Для ячейки А1, даты тоже можно вводить (с точками)

Private Sub Worksheet_Change(ByVal Target As Range)
  Set Target = Intersect(Target, Range("A1"))
  If Not Target Is Nothing Then
    If VarType(Target.Value2) <> vbDouble Then
      Application.EnableEvents = False
      Target.FormulaLocal = Replace(Target, ".", ",")
      Application.EnableEvents = True
    End If
  End If
End Sub

[ольгаг]

Спасибо!
Да, нужно вводить только числа, но если ввести, например, 12.45 ,
то подстановки точки запятой не происходит, т.е. срабатывает другое событие (преобразование числа в дату), которое в итоге показывает число 16772,00.
Подскажите пожалуйста, как отменить это событие, чтобы только работало событие кода:

Private Sub Worksheet_Change(ByVal Target As Range)
  Set Target = Intersect(Target, Range("A1"))
  If Not Target Is Nothing Then
    If VarType(Target.Value2) <> vbDouble Then
      Application.EnableEvents = False
      Target.FormulaLocal = Replace(Target, ".", ",")
      Application.EnableEvents = True
    End If
  End If
End Sub

[ольгаг]

Если поставить перед числом знак апострофа, то вроде бы замена числа на дату не работает. Подскажите пожалуйста, как кодом отследить событие ввода числа в ячейку и по нажатию enter (завершение ввода) добавить апостроф перед введенным числом?
Спасибо!

[Казанский]

Обработчик события Worksheet_Change вызывается уже после того, как нажат Enter и значение преобразовано по алгоритму Excel - то есть когда "12.45" уже преобразовано в дату.
Однако, если установить ячейке текстовый формат ячейки (Ctrl+1 - Число - Текстовый), то Excel не будет преобразовывать введенный текст, и это можно сделать в обработчике:

Private Sub Worksheet_Change(ByVal Target As Range)
Dim s$
  Set Target = Intersect(Target, Range("A1"))
  If Not Target Is Nothing Then
    On Error Resume Next
    Application.EnableEvents = False
    s = Replace(Target, ".", ",")
    If IsNumeric(s) Then
      Target.Value = CDbl(s)
    Else
      Application.Undo
      MsgBox "Введено не число", vbExclamation
    End If
    Target.NumberFormat = "@" 'на всякий случай
    Application.EnableEvents = True
  End If
End Sub

[ольгаг]

Спасибо, работает!
Только на попытку удалить значение из ячейки А1 выходит сообщение MsgBox "Введено не число", vbExclamation.

[Казанский]

Добавил проверку на пустоту

Private Sub Worksheet_Change(ByVal Target As Range)
Dim s$
  Set Target = Intersect(Target, Range("A1"))
  If Not Target Is Nothing Then
    On Error Resume Next
    s = Replace(Target, ".", ",")
    If Len(s) Then
      Application.EnableEvents = False
      If IsNumeric(s) Then
        Target.Value = CDbl(s)
      Else
        Application.Undo
        MsgBox "Введено не число", vbExclamation
      End If
      Target.NumberFormat = "@" 'на всякий случай
      Application.EnableEvents = True
    End If
  End If
End Sub

[ольгаг]

Спасибо большое!