Как оптимизировать макрос

[evdss]

Добрый день!
Подскажите, пожалуйста, как оптимизировать макрос? Записей в таблице много, работает очень медленно.

Sub Макрос1()
Dim W1 As Workbook
Set W1 = Application.Workbooks("11.xlsm")
    Dim i, j, iLastrow As Long, iLastcol As Long

W1.Activate
With W1.Sheets(1)
  iLastrow = .Cells(Rows.Count, 1).End(xlUp).Row
 iLastcol = Cells(2, Columns.Count).End(xlToLeft).Column
For i = 2 To iLastrow
For j = 7 To iLastcol Step 3
   Cells(i, j).FormulaR1C1 = "=RC[-1]-RC[-2]"
 Next
Next
End With
End Sub

[Aleksandr H.]

1. отключить на время обновление формул/перерисовку экрана
2. заполнить формулами 7 столбец
3. копировать/вставлять столбец формул п.2 до iLastCol Step 3
4. включить п.1

[SAS888]

Лучше всего, сначала определить диапазон для вставки формул, а затем их вставить.
Например, так:

Sub qq()
    Dim i As Long, a As Long, b As Long, x As Range
    Application.ScreenUpdating = False
    Workbooks("11.xlsm").Sheets(1).Activate
    a = Cells(Rows.Count, 1).End(xlUp).Row
    b = Cells(2, Columns.Count).End(xlToLeft).Column
    For i = 7 To b Step 3
        If x Is Nothing Then Set x = Cells(1, i) Else Set x = Union(x, Cells(1, i))
    Next
    Intersect(Rows("2:" & a), x.EntireColumn).FormulaR1C1 = "=RC[-1]-RC[-2]"
End Sub

[evdss]

Спасибо большое, работает очень быстро.