Копирование данных "отталкиваясь" от последней заполненой строки

[СтаСС]

Задача казалось бы легкая есть данные (для примера в столбцах A:G) и нужно скопировать данные одной строки и вставить в определенную-другую строку этого же листа в диапазон например H:N или O:U и тд.
Трудность для меня заключается в том что строки каждый день добавляются и для работы макросу нужно "отталкиваться" от последней строки с данными(снизу) поэтому прошу помочи разобраться как это сделать (пытался сам написать, но даже показывать не буду то что у меня получалось, верней не получилось, чтоб никто не смеялся и не плакал )

Для примера я выбрал пару действий чтоб понять сам принцип.. допустим надо:

с пред-пред-предпоследней строки (в примере 7-я строка) скопировать A:G и вставить в пред-предпоследнюю (в примере 8-я) в H:N
с пред-предпоследней строки (8-я) скопировать A:G и вставить в предпоследнюю (9-я) в H:N
с пред-пред-пред-предпоследней строки (6-я) скопировать A:G и вставить в пред-пред-предпоследнюю (7-я) в O:U
с пред-пред-предпоследней строки (7-я) скопировать A:G и вставить в предпоследнюю (9-я) в O:U

Вставлять надо сохранив значение и исходное форматирование, то есть:

Selection.PasteSpecial Paste:=xlPasteAllUsingSourceTheme, Operation:=xlNone _
        , SkipBlanks:=False, Transpose:=False
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False

[Aleksandr H.]

Сообщение от СтаСС

Трудность для меня заключается в том что строки каждый день добавляются и для работы макросу нужно "отталкиваться" от последней строки с данными(снизу)

Последняя строка столбца А

rowsCount = Cells(Rows.Count, "A").End(xlUp).Row

[СтаСС]

Сообщение от Aleksandr H.

[/CODE]

Этот код я знаю.. игрался с ним целый день вот так например пробовал:

 Dim ra As Range, rb As Range, rd As Range, cc As Range, ccc As Range
 Application.ScreenUpdating = False
 
 Set ra = Range(.Range("A" & .Rows.Count).End(xlUp), .Range("G" & Rows.Count).End(xlUp))

    Selection.Copy
Set ra = Range(.Range("H" & .Rows.Count).End(xlUp), .Range("N" & Rows.Count).End(xlUp))
 End With
 
    Selection.PasteSpecial Paste:=xlPasteAllUsingSourceTheme, Operation:=xlNone _
        , SkipBlanks:=False, Transpose:=False
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False

    Application.CutCopyMode = False

End Su

ну не получается у меня короче... знаний не хватает.. надо чтоб кто-то разжевал основательно )))

[Aleksandr H.]

Sub CopyMyRange()
    Dim LastRow As Integer
    Dim upOffset As Byte
    Dim rowNumber As Integer
    Dim rngFrom As Range
    LastRow = Cells(Rows.Count, "A").End(xlUp).Row
    upOffset = CInt(InputBox("Введите количество строк для отступа с конца", "парамерт 1", 2))
    
    rowNumber = Application.WorksheetFunction.Max(1, LastRow - upOffset)
    Set rngFrom = Range("A" & rowNumber & ":G" & rowNumber)
    rngFrom.Copy
    
    upOffset = CInt(InputBox("Введите количество строк c конца для вставки", "парамерт 1", 2))
    rowNumber = Application.WorksheetFunction.Max(1, LastRow - upOffset)
    
    With Cells(rowNumber, "H")
        .PasteSpecial Paste:=xlPasteAllUsingSourceTheme, Operation:=xlNone _
            , SkipBlanks:=False, Transpose:=False
        .PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
            :=False, Transpose:=False
    End With
End Sub

[СтаСС]

Сообщение от Aleksandr H.

,

Вот это уже лучше!
Для такого старого неуча как я - то что надо!
Большое спасибо! Буду пробовать.

[Казанский]

Sub St()
Dim n&
  n = Cells(Rows.Count, "A").End(xlUp).Row 'последняя строка

'с пред-пред-предпоследней строки (в примере 7-я строка) скопировать A:G и вставить в пред-предпоследнюю (в примере 8-я) в H:N
  Range("A1:G1").Rows(n - 3).Copy Cells(n - 2, "H")
  
'с пред-предпоследней строки (8-я) скопировать A:G и вставить в предпоследнюю (9-я) в H:N
  Range("A1:G1").Rows(n - 2).Copy Cells(n - 1, "H")

'с пред-пред-пред-предпоследней строки (6-я) скопировать A:G и вставить в пред-пред-предпоследнюю (7-я) в O:U
  Range("A1:G1").Rows(n - 4).Copy Cells(n - 3, "O")

'с пред-пред-предпоследней строки (7-я) скопировать A:G и вставить в предпоследнюю (9-я) в O:U
  Range("A1:G1").Rows(n - 3).Copy Cells(n - 1, "O")
End Sub

Формировать диапазоны по смещению можно разными способами - см. F1 - Offset, Resize. Я выбрал тот, при котором константа равна числу "пред" в описании команды.

[СтаСС]

Сообщение от Казанский

[CODE]Sub St()

Отлично, ваш вариант возьму за основу т.к. нужен макрос с сотнями копирований и вставок за раз, а макрос Aleksandr H. пригодится когда будут нужны изменения.
Спасибо ВАМ!!!