Вложенная панель инструментов.

[haros]

Привет всем!
Есть такая проблемка... Существует некая база и в этой книге вложена Панель инструментов "Сотрудники" на кнопочки которой назначены макросы для работы с этой базой.
Отсюда возникает вопрос, как сделать так, чтоб при открытии этой конкретной книги отображалась только нужная мне панель инструментов, а при закрытии книги она (панель Сотрудники) убиралась из списка Панелей инструментов и все возвращалось на место?????

[EducatedFool]

В модуль "Эта книга" пишем код:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Application.CommandBars("Сотрудники").Visible = False
End Sub

Private Sub Workbook_Open()
    Application.CommandBars("Сотрудники").Visible = True
End Sub

Если что-то не будет получаться, прикрепите к сообщению файл.

[haros]

Понимаете уважаемый, мне нужно все остальные панели и меню при открытии прятать, а после закрытия возвращать назад, чтоб в других книгах все было пучком!

[EducatedFool]

Ну тогда так:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    RestoreInterface
End Sub

Private Sub Workbook_Open()
    UserInterface
End Sub


Sub UserInterface(): ChangeInterface False: End Sub    ' скрывает всё лишнее с экрана

Sub RestoreInterface(): ChangeInterface True: End Sub    ' восстанавливает всё как было

Sub ChangeInterface(Value As Boolean)
    On Error Resume Next
    With Application
        .ScreenUpdating = False: .Caption = IIf(Value = True, Empty, "Мой заголовок окна Excel")
        .DisplayStatusBar = Value: .DisplayFormulaBar = Value
        For Each iCommandBar In .CommandBars
            iCommandBar.Enabled = Value
        Next
        With .ActiveWindow
            .Caption = IIf(Value = True, .Parent.Name, "")
            .DisplayHeadings = Value: .DisplayGridlines = Value
            .DisplayHorizontalScrollBar = Value: .DisplayVerticalScrollBar = Value:
            .DisplayWorkbookTabs = Value
        End With: .ScreenUpdating = True
        .CommandBars("Сотрудники").Enabled = Not Value
    End With
End Sub

[haros]

Большое спасибо, чуток подработав под себя получил нужный результат!

[haros]

Какая организовалась проблемка: если открыта книга с нашим запущенным макросом и при этом открыть другую книгу, то действие макроса распространяется и на нее... можно этого как-то избежать???

[EducatedFool]

Вместо первых двух макросов поставьте четыре:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    RestoreInterface
End Sub

Private Sub Workbook_Deactivate()
    RestoreInterface
End Sub

Private Sub Workbook_Open()
    UserInterface
End Sub

Private Sub Workbook_Activate()
    UserInterface
End Sub

[haros]

и снова благодарю!