Как поставить пробел, через 8 знаков

[valerij]

Как поставить пробел, через 8 знаков. В аттаче текстовый файл, сохранить нужно в том же формате(или doc)
Фрагмент примера:

Исходник
55aa7be91102000000000000000000000000000000000000c40100000000494.........
Результат
55aa7be9 11020000 00000000 00000000 00000000 00000000 c4010000 00004942 ........

Вот макрос для этого(может кому пригодится)

Sub Пробел()
For f = 0 To 20000 ' Количество строк
    Selection.MoveRight Unit:=wdCharacter, Count:=8
    Selection.TypeText Text:=" "
    Next
End Sub

[Sasha_Smirnov]

Если тема интересна, то смотреть лучше тут.

А мой вариант работает с 16-теричными цифрами прямо в окне Word.

Sub SwitchSandwich() 'находит в тексте восьмёрки 16-теричных цифр и разделяет их пробелами'

Static odd As Boolean  'переменная, отслеживающая нечётные вызовы'
odd = Not odd
Selection.HomeKey wdStory           'курсор - в начало документа Word'

With Selection.Find
    
    Select Case odd
    Case True
        .Text = "([0-9A-Fa-f]{8})"                  'очередные 8 шестнадцатеричных цифр'
        .Replacement.Text = "\1" & Space(1) 'добавляем пробел к группе из 8 цифр'
    Case False
        .Text = "([0-9A-Fa-f]{8}) "         'очередные 8 шестнадцатеричных цифр и пробел'
        .Replacement.Text = "\1"            'убираем пробел после группы из 8 цифр'
    End Select
    
        .MatchWildcards = True              'отмечен флажок Подстановочные знаки'
        .Wrap = wdFindContinue          'переходим (после добавления) к очередной группе'
        .Execute Replace:=wdReplaceAll  'выполнение замены'
        
        .Text = ""                               'очистка поля Найти:'
        .Replacement.Text = ""          'очистка поля Заменить на:'
        .MatchWildcards = False         'сброс флажка Подстановочные знаки'
        .Execute                                  'выполнение очистки'
        
End With

End Sub

[valerij]

Сообщение от Sasha_Smirnov

Если тема интересна, то смотреть лучше тут.

Видел, ну с Excel -ем все понятно, а вот почему в Word -е, так, см. скрин, красным, не 8 разрядов, а четыре??

[Sasha_Smirnov]

Так мой код был написан. Он только 4-байтовые (по 8 цифр) "слова" снабжает пробелом. А каждое 8-е слово в вашем биосе — двухбайтовое (4 цифры), а за ним сразу идёт символ-терминатор (который выглядит в word-документе как знак абзаца).

Я без понятия, считываются ли эти "абзацы" при загрузке, иначе говоря — важны ли они как кодовые символы. Вот так и сделал.

Кстати, у меня секунд за 30—40 ваш текст "прошился" пробелами. А вообще-то поиск (многократный) в формате doc(x) — вещь не суперскоростная, быстрее в txt. Ну, ради разнообразия, прилагаю следующий

Sub OctSandwich() 'Находит в тексте восьмёрки 16-теричных цифр, добавляя после них пробел.
'При этом в тексте до 16-теричных цифр не должно быть других цифр, идущих более трёх подряд.'

Selection.HomeKey wdStory               'курсор - в начало документа Word'

With Selection.Find
    
.Text = "([0-9a-f]{4}*[0-9a-f]{4})" 'очередные 8 шестнадцатеричных цифр'
.Replacement.Text = "\1" & " "          'добавляем пробел к группе из 8 цифр'

.MatchWildcards = True              'в окне (по Ctrl-F) отмечен флажок Подстановочные знаки'
.Wrap = wdFindContinue              'переходим (после добавления) к очередной группе'
.Execute Replace:=wdReplaceAll  'выполнение замены'

.Text = ""                               'очистка поля Найти:'
.Replacement.Text = ""          'очистка поля Заменить на:'
.MatchWildcards = False         'сброс флажка Подстановочные знаки'
.Execute                                  'выполнение очистки'
        
End With
End Sub