Работа с массивами

[mchip]

Подскажите как убрать заданную область из массива
Например:

массив(1 to 5, 1 to 3)

как убрать массив (4, 1), массив(4, 2), массив (4,3).

не обнулить а удалить!

[IgorGO]

что значит убрать? 5-ю строку сделать четвертой?

[mchip]

Да, а 4 удалить

[HighStar]

Ну, как я понял, Вы хотите удалить из массива все элементы строки (столбца - не суть). Насколько мне известно, это возможно для динамических массивов и только для последней размерности массива.
То есть, задача была бы разрешима, если поменять размерности местами.
Например,
Dim Ar(1 to 3, 1 to 5)
Удалить 4-й столбец, т.е. Ar(1, 4), Ar(2, 4), Ar (3,4).
Вариант решения -

Sub Del4Column()
Dim Ar()
ReDim Ar(1 To 3, 1 To 5)
Dim r As Long, c As Long
'массив заполнил для теста, ну и чтоб понятнее было
For r = 1 To 3
  For c = 1 To 5
    Ar(r, c) = r & c
  Next c
Next r
'переносим пятый столбик в четвертый
For r = 1 To 3
  Ar(r, 4) = Ar(r, 5)
Next r
'удаляем пятый столбик
ReDim Preserve Ar(1 To 3, 1 To 4)
End Sub

Да, и если после удаляемого столбца более одного перемещаемого, придется в перенос вложить ещё один цикл.

[SAS888]

это возможно для динамических массивов и только для последней размерности массива.

Абсолютно согласен. Но кто нам мешает транспонировать массивы? Удалить 4-ю строку можно так:

Sub Del4Row()
    Dim r As Long, c As Long, a()
    ReDim a(1 To 5, 1 To 3)
'Заполняем массив (для наглядности)
    For r = 1 To 5
        For c = 1 To 3
            a(r, c) = r + c
        Next
    Next
'Пусть "a" - это данный динамический массив, в котором нужно удалить 4-ю строку.
'переносим пятую строку в четвертую
    For c = 1 To 3
        a(4, c) = a(5, c)
    Next
    a = Application.Transpose(a) 'транспонируем массив
    ReDim Preserve a(1 To 3, 1 To 4) 'удаляем 5-й столбец
    a = Application.Transpose(a) 'транспонируем массив
End Sub

[mchip]

А если столбиков (строк) сотни (тысячи)?

[SAS888]

Существует множество вариантов. Например, очистить все не нужные строки (столбцы), затем передвинуть все пустые строки (столбцы) в конец данной размерности, а затем изменить размерность с сохранением значений элементов массива. Можно применить сортировку и т.д. и т.п. Если же, Вам нужно строго удалить одну строку (столбец), и при этом нет никаких дополнительных, облегчающих (и, следовательно, ускоряющих) работу критериев, то тогда понадобится, как говорил HighStar, дополнительный цикл по передвижке строк (столбцов).

[mchip]

Спасибо! Видимо прийдется форматировать и обрабатывать на листе в ячейках.

[SAS888]

Подумайте еще раз...
При больших объемах данных, скорее всего, не смотря на возможно большее количество циклов, работа с массивами будет существенно быстрее, чем непосредственно с ячейками.