Как объявить диапазон ячеек при известных границах

[motorway]

Как объявить диапазон ячеек при известных ограничивающих его столбце и строке в численном виде, чтобы можно было потом его использовать в цикле For Each?
Имеются цифры row, col, например 2, 4. Нужно получить в этом случае объект Range (A2:D4).

[EducatedFool]

Не совсем понял, как из цифр 2 и 4 получить диапазон A2:D4...

Sub test()
    Row = 2: col = 4
    Dim cell As Range, ra As Range

    Set ra = Range("a" & Row & ":d" & col) ' попробуйте так
    Set ra = Range([a2], Cells(Row, col)) ' или так
    Set ra = Range(Cells(Row, "A"), Cells(col, col)) ' ещё вариант

    For Each cell In ra.Cells
        ' обработка ячеек
        cell = Rnd: cell.Interior.ColorIndex = Rnd * 50
    Next cell
End Sub

[motorway]

Я от усталости написал случайно не точно. На самом деле я хотел получить по цифре 2 нижнюю границу для строки, а 4 - столбец D. То есть 8 ячеек: A1,A2,B1,B2,C1,C2,D1,D2.
Но мне нужно, чтобы само определялось, что за буква будет, т.е. необяз. все время D.

Кстати, вот еще есть вариант, но не работает проход по циклу:
Dim a As Range

a = Range(Cells(1, 1), Cells(2, 4))

For Each cell In a
MsgBox (cell.Text)
Next cell

Object variable or with block variable not set

[EducatedFool]

Sub test()
    Dim a As Range, cell As Range
    Set a = Range(Cells(1, 1), Cells(2, 4))
    For Each cell In a
        MsgBox cell.Text
    Next cell
End Sub

В Вашем случае может получиться так:

Sub test1()
    Dim a As Range, cell As Range
    ro = 2: col = 4
    Set a = Range(Cells(1, 1), Cells(ro, col))
    For Each cell In a
        MsgBox cell.Text
    Next cell
End Sub

Sub test2()
    Dim a As Range, cell As Range
    ro = 2: col = 4
    Set a = Cells(1, 1).Resize(ro, col)
    For Each cell In a
        MsgBox cell.Text
    Next cell
End Sub

Sub test3()
    ro = 2: col = 4
    For Each cell In Cells(1, 1).Resize(ro, col)
        MsgBox cell.Text
    Next cell
End Sub

[IgorGO]

теперь многие, кто тут бывает в непонятках "что, собственно, нужно получить?"

диапазон всегда начинается с А1 а заканчивается рядом row и колонкой col? Так?

приведено 3 способа получения нужного диапазона и приведен цикл For Each, который обходит все ячейки диапазона (каждой из ячеек присваивает случайное значение и закрашивает случайным цветом). 2-й из приведенных способ никак не ссылается на колонку D.

еще вариант:
Set ra = Range(cells(1,1), cells(row, col))

[motorway]

Для моего случая всегда с A1, но может быть и типа I13:J16

[motorway]

У меня еще проблема с тем, что я определяю данный диапазон для нескольких листов в цикле:

For i = 1 To (Worksheets.Count - 1)
    Dim TRange As Range, cell As Range
    Set TRange = Range(Worksheets(i).Cells(1, 1), Cells(Worksheets(i).Cells.SpecialCells(xlCellTypeLastCell).Row, Worksheets(i).Cells.SpecialCells(xlCellTypeLastCell).Column))
    For Each cell In TRange
....

Что-то я запутался, как правильно в цикле по листам кроме последнего объявить такой диапазон, где используются ячейки листа от A1 до нижней правой используемой границы.

Method Range of object _Global Failed

[EducatedFool]

Sub test4()
    Dim sh As Worksheet, TRange As Range, cell As Range

    For i = 1 To (Worksheets.Count - 1)
        Set sh = Worksheets(i)
        Set TRange = Range(sh.Cells(1, 1), sh.Cells.SpecialCells(xlCellTypeLastCell))

        For Each cell In TRange
            MsgBox cell.Text
        Next cell
    Next i
End Sub

Sub test5()
    Dim TRange As Range, cell As Range
    For i = 1 To (Worksheets.Count - 1)
        For Each cell In Worksheets(i).UsedRange.Cells
            MsgBox cell.Text, vbInformation, _
                   "Ячейка " & cell.Address & " на листе " & Worksheets(i).Name
        Next cell
    Next i
End Sub

[motorway]

Спасибо. Больше подходит первый вариант, т.к. в варианте с UsedRange пустые ячейки игнорируются, а мне нужно их тоже передавать, поэтому я и отказался от UsedRange.

[nikolainikitin]

Здравствуйте, Уважаемые коллеги.
Извините что не совсем в тему сайта www.programmersforum.ru обращаюсь,
давно хочу открыть форум про пневматическое оружие, но никак с движком форума определиться не могу.
Нужен ведь движок форума с нормальной защитой от спама, а то мой друг себе форум установил и его заполнили спамом уже через 2 недели.
А Вы какой движок сайта на www.programmersforum.ru используете? Какой скрипт форума лучше выбрать для открытия форума про пневматическое оружие?
Буду рад любому совету, в заранее спасибо.

С уважением Николай.