Копирование из закрытой книги

[Maxx]

Добрый день!

Вот уже несколько дней бьюсь над этой темой - результат нулевой

Задание:

В файл Total.csv надо поместить данные из файлов A.csv и AA.csv, лежащих в папке "A".

В файле Total.csv данные должны размещаться в одну колонку в столбце A неразрывно, начиная с ячейки A1.

Макрос на выполнение данной процедуры должен запускаться из книги Main.xlsm

Копирование в Total.csv должно быть без открытия A.csv и AA.csv

Помогите, пожалуйста! Или дайте идею хоть какую-нибудь!

[Chelentano]

Привет! Я сам новичок, не знаю, как оно работает с csv-файлами, но c xls когда-то слышал, что можно в коде макроса попробовать что-то типа такого:

Sub Копирование_книг()
Application.ScreenUpdating=False 'эта команда по- моему позволяет пользователю не видеть, что делает макрос и ускоряет вообще работу макроса
Workbooks("A.xls").Open
Wokbooks("AA.xls").Open

'далее идут команды копирования и вставок между книгами

Workbooks("A.xls").Close
Wokbooks("AA.xls").Close

Application.ScreenUpdating=True


End sub

[doober]

Документы будут находиться постоянно в определенных папках,или нет?

[doober]

Я думаю средсвами Excel без открытия не получиться,попробуйте сторонее приложение,что не понятно,пишите в личку,или мыло

[doober]

Был не прав по поводу возможностей Excel
Формат csv можно открыть как тектовый документ
Как открыть описано здесь.
http://programmersforum.ru/showthrea...F2%EE%E2%FB%E9

[SAS888]

Посмотрите вложение. Откройте файл "Main" и запустите макрос "Main".
ВАЖНО: файл "Total.csv" должен находиться в той же папке, что и файл "Main".

[Maxx]

SAS888, спасибо за неоценимую помощь! Все работает!

А я пытался сделать по следующей схеме:
With ThisWookbook.WorkSheet(1)
Далее цикл по перебору строк
Ячейка в Total = Ячейка в A.csv (указав на этот файл полный путь и имя листа)

В итоге - НЕ ВЫШЛО :-(

Если не затруднит:

Sub Main()
    Dim myPath As String, myName As String, fso, tsW
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set tsW = fso.OpenTextFile(ThisWorkbook.Path & "\Total.csv", 2, True)
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "Укажите рабочую папку"
        .Show
        If .SelectedItems.Count = 0 Then Exit Sub
        myPath = .SelectedItems(1) & "\"
    End With
    myName = Dir(myPath & "*.csv")
    Do While myName <> ""
        tsW.Write fso.OpenTextFile(myPath & myName, 1).ReadAll
        myName = Dir
    Loop
    tsW.Close
End Sub

Что делают эти строки (мне для дальнейшего развития)?

И можно ли заменить выбор папок на автоматический (помимо папки А будет еще только папка B во все тойже папке Total). Структура папок меняться не будет.

[SAS888]

Что делают эти строки

1. Set fso = CreateObject("Scripting.FileSystemO bject") - создаем объект Scripting.FileSystemObject.
2. tsW.Write fso.OpenTextFile(myPath & myName, 1).ReadAll - в файл, открытый для записи (Set tsW = fso.OpenTextFile(ThisWorkbook.Path & "\Total.csv", 2, True)), записываем данные, считанные из файла, открытого для чтения (весь файл разом).
3. myName = Dir - переходим к следующему файлу в той же директории, удовлетворяющему условию Dir(myPath & "*.csv").

можно ли заменить выбор папок на автоматический

Для этого нужен список папок и путей их расположения.

[Maxx]

Для этого нужен список папок и путей их расположения.

Все будет именно так и НЕ КАК НЕ ПО ДРУГОМУ (кроме имен файлов и папок):

Total - в ней папка A с файлами A и AA.csv и папка B с файлами B и BB.csv

Также в папке Total лежит файл с макросом Main.xlsm и обобщающий файл Total.csv

создаем объект Scripting.FileSystemObject

надо будет початать что это такое

[Maxx]

Сделал методом тупого перебора :-)))

Sub Main()
    Dim myPathA, myPathB As String, myName As String, fso, tsW
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set tsW = fso.OpenTextFile(ThisWorkbook.Path & "\Total.csv", 2, True)
    
    Cells.ClearContents
    
    myPathA = ThisWorkbook.Path & "\A\"
    myPathB = ThisWorkbook.Path & "\B\"
    
    myName = Dir(myPathA & "*.csv")
    Do While myName <> ""
        tsW.Write fso.OpenTextFile(myPathA & myName, 1).ReadAll
        myName = Dir
    Loop
    
    myName = Dir(myPathB & "*.csv")
    Do While myName <> ""
        tsW.Write fso.OpenTextFile(myPathB & myName, 1).ReadAll
        myName = Dir
    Loop
    tsW.Close
End Sub