Разделение строки по критерию

[mephist]

Вынужден обратиться с пустяковым вопросом.
Мне нужно разделить полный путь к файлу.
То есть, имеется строка в ячейке A1 "D:\fol1\1.txt",
я хочу, чтобы в строке А2 оказалось "D:"
в строке А3 оказалось "fol1"
в строке А4 оказалось "1.txt"
Сделал бы сам, но не знаю как поэлементно обращаться к символам строки(в Паскале было такое:

m : string;
If m[i]='\' then ...

).
А вот как сделать это самое m[i]= ????

А нельзя ли использовать Экселевские примочки??? Я знаю что такая задача решается легко автоматически при загрузке текстового файла, если в качестве разделителя взять "\". Нельзя ли это как-нибудь приспособить к моему случаю???

[The_Prist]

A1 = "D:\fol1\1.txt"

if [a1] like "*\*" then [А2] = Split([A1])(0):[А3] = Split([A1])(1):[А4] = Split([A1])(2)

[mephist]

супер! как раз то, что нужно. можно один уточняющий вопрос: как мне провести эту процедуру в цикле, если я не знаю сколько раз будет встречаться /
То есть:

    For j = 1 To .UsedRange.Rows.Count
        If Cells(j, 1) Like "*\*" Then
            For k = 1 To MMM
                Cells(j + k, 1) = Split(Cells(j, 1))(k - 1)
            Next k
    Next j

Я не знаю, какой длины будет путь и сколько раз встретится /,поэтому
Что мне поставить вместо MMM???

[IgorGO]

Sub DirSplit()
s = "D:\fol1\1.txt"
c = 1
p1 = 1: p2 = 0
For ch = 1 To Len(s)
If Mid(s, ch, 1) = "\" Then
p2 = ch
Cells(1, c) = Mid(s, p1, p2 - p1)
c = c + 1
p1 = p2 + 1
End If
Next
Cells(1, c) = Mid(s, p1, 1000)
End Sub

Mid аналог паскалевского m[i]

[doober]

Твой фрагмент,с исправлениями

Dim v As Variant
Dim s As String
 For j = 1 To .UsedRange.Rows.Count
        If Cells(j, 1) Like "*\*" Then
        s = Cells(j, 1)
        v = Split(s, "\", -1)
        
        
        
            For k = 0 To UBound(v)
                Cells(j + k, 1) = v(k)
            Next k

         end if   
    Next j

UBound (функция) - возвращает значение наибольшего индекса для данной размерности массива

[Aent]

Всё несколько проще

Public Sub MySpliter(r As Range)
    If r.Cells.Count > 1 Then Exit Sub
    r.Offset(1, 0).Resize(UBound(Split(r.Value, "\")) + 1, 1) = Application.Transpose(Split(r.Value, "\"))
End Sub

Разумеется, split можно генерализовать, введя временную переменную
А можно и без VBA (Предполагается что исходная строка в ячейке A1)
Определим имя EVAL как =ВЫЧИСЛИТЬ("{""" &ПОДСТАВИТЬ($A$1;"\";""";""")&"""}" )
В ячейки A2:An поместим массивную формулу ={ТРАНСП(EVAL)}
Отмечу, что последний приведённый способ имеет естественное ограничение на длину аргумента функции XLM ВЫЧИСЛИТЬ. Эта длина не может превосходить 256 символов.

[mephist]

Код высший класс! Огромное спасибо. Но я если честно, чуть-чуть не так работает. Мне нужно, чтобы он разделял строку, помещая части пути в ту же строку. А у Aent он размещает их в тот же столбец.
То есть строку D:\fol1\1.txt он размещает так:
D:
fol1
1.txt
А мне нужно, так:
D: fol1 1.txt
Пока мне удалось добиться только такого:

Public Sub MySpliter(ByVal r As Range)
    If r.Cells.Count > 1 Then Exit Sub
    r.Offset(0, 1).Resize(1, UBound(Split(r.Value, "\")) + 1) = Application.Transpose(Split(r.Value, "\"))
End Sub

Который делает так:
D: D: D:
Подскажите, пожалуйста, что нужно поправить???

[Aent]

Mephist, в первом посте вы пишите

я хочу, чтобы в строке А2 оказалось "D:"
в строке А3 оказалось "fol1"
в строке А4 оказалось "1.txt"

- это распределение по строкам ...
Если нужно по столбцам, то код

Public Sub MySpliter(ByVal r As Range)
    If r.Cells.Count > 1 Then Exit Sub
    r.Offset(0, 1).Resize(1, UBound(Split(r.Value, "\")) + 1) = Split(r.Value, "\")
End Sub

Split возвращает"массив-строку" так что транспонировать результат с помощью функции листа Transpose не нужно.

[mephist]

Спасибо большое. Очень помогли!!!

[SAS888]

Или еще проще, например, для ячейки "A1":

MsgBox Split([A1], "\")(0)