Проблема с контекстном меню в Excel 2007

[Shlyapnik]

Ситуация следующая:

Нарыл где-то пример создания собственного контекстного меню в Excel. Запустил, да действительно пример полностью раскрывает тему, но после него у меня пропало вообще в Excelе 2007 любое контекстное меню при работе с ячейками , пробовал полную переустановку офиса, не помогло . Пожалуйста, кто знает подскажите как вернуть стандартное контекстное меню, без него не как.

Option Explicit
 
Const PopUpCommandBarName As String = "TemporaryPopupMenu"

Sub DeletePopUp()
    On Error Resume Next
    CommandBars(PopUpCommandBarName).Delete
    On Error GoTo 0
End Sub

Sub CreatePopUp()
Dim cb As CommandBar, m As CommandBarPopup
    DeletePopUp
    Set cb = CommandBars.Add(PopUpCommandBarName, msoBarPopup, False, True)
    With cb
        With .Controls.Add(Type:=msoControlButton)
            .OnAction = "MyMacroName"
            .FaceId = 71
            .Caption = "Custom Menu 1"
            .TooltipText = "Custom Tooltip Text 1"
        End With
        With .Controls.Add(Type:=msoControlButton)
            .OnAction = "MyMacroName"
            .FaceId = 72
            .Caption = "Custom Menu 2"
            .TooltipText = "Custom Tooltip Text 2"
        End With
        With .Controls.Add(Type:=msoControlButton)
            .OnAction = "MyMacroName"
            .FaceId = 73
            .Caption = "Custom Menu 3"
            .TooltipText = "Custom Tooltip Text 3"
        End With
    
        Set m = .Controls.Add(Type:=msoControlPopup)
        With m
            .BeginGroup = True
            .Caption = "Sub Menu"
            
            With .Controls.Add(Type:=msoControlButton)
              .OnAction = "MyMacroName"
              .FaceId = 71
              .Caption = "Custom Menu 1"
              .TooltipText = "Custom Tooltip Text 1"
            End With
            With .Controls.Add(Type:=msoControlButton)
              .OnAction = "MyMacroName"
              .FaceId = 72
              .Caption = "Custom Menu 2"
              .TooltipText = "Custom Tooltip Text 2"
            End With
            With .Controls.Add(Type:=msoControlButton)
              .OnAction = "MyMacroName"
              .FaceId = 73
              .Caption = "Custom Menu 3"
              .TooltipText = "Custom Tooltip Text 3"
            End With
        End With
        Set m = Nothing
        
    End With
    Set cb = Nothing
End Sub

Sub DisplayCustomPopUp()
    On Error Resume Next
    Application.CommandBars(PopUpCommandBarName).ShowPopup
    On Error GoTo 0
End Sub

Sub DisplayExampleUserForm()
    Load UserForm1
    UserForm1.Show
    Unload UserForm1
End Sub

Sub MyMacroName()
Dim ctrl As CommandBarControl
    If Not UserForm1.Visible Then
        Set ctrl = Application.CommandBars.ActionControl
        ActiveCell.Formula = ctrl.Caption
        Set ctrl = Nothing
    Else ' the UserForm is visible
        If Application.International(xlCountrySetting) = 47 Then
            MsgBox "Dette kunne vært din egen makro som kjørte!", vbInformation, ThisWorkbook.Name
        Else
            MsgBox "This could be your macro running!", vbInformation, ThisWorkbook.Name
        End If
    End If
End Sub


Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    Cancel = True
    DisplayCustomPopUp
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    DeletePopUp
End Sub

Private Sub Workbook_Open()
    CreatePopUp
End Sub

Исходник не выкладываю чтобы не кто случайно не лишился своего popupmenu , если вдруг нужно будет выложу.

[The_Prist]

Попробуйте выполнить такой макрос:

Sub Reset_CBar()
Application.CommandBars("Cell").Reset
End Sub

[Shlyapnik]

Макрос выполнился успешно. Но результат тот же

[Shlyapnik]

The_Prist спасибо за наводку. Поэкспериментировал с твои примером, после добавления строки

Application.CommandBars("Cell").Reset
Application.CommandBars("Cell").Enabled = True

все заработало!

[Shlyapnik]

хм... оказывается это еще не все мои проблемы
popupmenu этой области тоже нет:



по аналогии я так понимаю проблема решится, только я не знаю как называется эта область, пробовал

Application.CommandBars("Sheet").Reset
Application.CommandBars("Sheet").Enabled = True

не помогло.

Может кто знает как называется эта область?

[EducatedFool]

Это Вам поможет:

Sub ВосстановитьВсеКонтекстныеМеню()
    Dim cb As CommandBar
    For Each cb In Application.CommandBars
        If cb.Type = msoBarTypePopup Then cb.Enabled = True: cb.Reset
    Next
End Sub

[Shlyapnik]

EducatedFool спасибо. Все заработало