Автоматическое заполнение ячеек (VBA)

[Warhead]

Нужно написать код, чтобы при открытии книги автоматически заполнялись ячейки с A1-A10 со значениями от 1-10.
Заранее спасибо за помощь!

[Dophin]

Private Sub Workbook_Open()
Dim i As Integer
Sheets(1).Cells(1, 1) = 1
For i = 2 To 10
Sheets(1).Cells(i, 1) = Sheets(1).Cells(i - 1, 1) + 1
Next i
End Sub

[SAS888]

Предлагаю другой вариант. Без цикла:

Private Sub Workbook_Open()
    [A1:A10] = "=Row()": [A1:A10] = [A1:A10].Value
End Sub

[Sasha_Smirnov]

Sub workbook_Open()
SendKeys "^{home}", True
SendKeys "{1}~{2}~{3}~{4}~{5}~{6}~{7}~{8}~{9}~{1}{0}~"
End Sub

срабатывает лишь находясь в папке ЭтаКнига. (Полчаса кумекал, чтоб это выяснить!)

[SAS888]

Сообщение от Sasha_Smirnov

Полчаса кумекал, чтоб это выяснить!

А зачем? Какой плюс у предложенного Вами способа? А если нужно "пронумеровать" миллион строк?

[Flangini]

Я прошу прощенье что пост немного не в тему, просто раз пошло такое дело, может как-то можно оптимизировать следующий код:

For j = 1 To 2 'Диапазон столбцов
For i = 2 To ActiveSheet.UsedRange.Rows.Count 'Диапазон строк
If Cells(i + 1, j).Value = 0 Then Cells(i + 1, j) = Cells(i, j) 'Заполнение
Next
Next

код применяется для заполнения пустых ячеек таблицы полученной путём копирования сводной

[SAS888]

Оптимизация данного кода зависит от многих факторов. В общем виде, увеличить скорость выполнения Вашей процедуры можно, если работать не с ячейками листа, а с элементами массива. Например, так:

Sub Main()
    Dim i As Long, x As Range, a(): Application.ScreenUpdating = False
    Set x = Range([A2], Cells(ActiveSheet.UsedRange.Rows.Count, 2)): a = x.Value
    For j = 1 To 2 'Диапазон столбцов
        For i = 2 To UBound(a, 1) 'Диапазон строк
            If a(i, j) = 0 Then a(i, j) = a(i - 1, j) 'Заполнение
    Next: Next: x.Value = a
End Sub

Если нулевых ячеек в диапазоне мало, то можно и по-другому, например, перебирать не все ячейки, а только пустые.
Есть еще ряд зависимостей: считать ли 0 и пустую ячейку равнозначными?, нужно ли заполнять все пустые (нулевые) ячейки значениями предыдущих, если они идут подряд?

[Flangini]

Ноль это ноль, то есть независимое значение, пустая яцейка - это пустая ячейка. У меня в примере ошибка

If Cells(i + 1, j).Value = 0

до этого работал с текстом вот и поставил ноль, правельней было бы написать

If Cells(i + 1, j).Value is Empty

или

If Cells(i + 1, j).Value is Null

странно - выдаёт ошибку "424" (не знаю что она означает)

нужно ли заполнять все пустые (нулевые) ячейки значениями предыдущих, если они идут подряд?

для этого и писался данный код.

[The_Prist]

Сообщение от Flangini

странно - выдаёт ошибку "424" (не знаю что она означает)для этого и писался данный код.

Ничего странного - нет такой конструкции - Cells(i + 1, j).Value is Null.
Пишите так

If IsEmpty(Cells(i + 1, j).Value) Then

А лучше так

If Cells(i + 1, j).Value = "" Then

[Flangini]

спасибо, что подсказали. Я слабо опытен в VBA, по роду своей деятельности приходится учиться что говориться "на ходу".