Как оставить только нужные строки?

[Palantir]

Добрый день, уважаемые форумчане!
Есть необходимость отредактировать все листы книги Excel по следующему принципу: оставить только строки 8-ю, 16-ю, 24-ю, 32-ю,..., 1608-ю, и т.д., то есть все строки, номер которых кратный восьми. (Или, соответственно, оставить только ячейки A8, A16,...). Остальную информацию за ненадобностью удалить. В приложенном файле тот самый документ. Конечно, у меня есть свой вариант решения задачи: посадить на полдня секретаршу для очистки документа вручную, однако согласитесь, способ "неспортивный". Может быть подскажете более интеллектуальное решение задачи?

[Dophin]

Sub pp()
Dim iL As Long
Dim sh As Worksheet
Dim i As Long
For Each sh In Worksheets
iL = sh.Cells(Rows.Count, 1).End(xlUp).Row
For i = 1 To iL
If Round(i / 8, 0) <> i / 8 Then
sh.Cells(i, 1).Clear
End If
Next i
Next sh
End Sub

[SAS888]

Можно чуть быстрее:

Sub Main()
    Dim i As Long, j As Long, ws As Worksheet, x As Range, a(), b()
    Application.ScreenUpdating = False
    For Each ws In Sheets
        Set x = ws.Range(ws.[A1], ws.Cells(Rows.Count, 1).End(xlUp)): a = x.Value
        ReDim b(1 To UBound(a, 1), 1 To 1): j = 1
        For i = 8 To UBound(a, 1) Step 8
            b(j, 1) = a(i, 1): j = j + 1
        Next
        ws.[A:A].ClearContents: x.Value = b
    Next
End Sub

Пример во вложении. Запустите макрос "Main".

[Dophin]

SAS888:
а зачем Вы пишите код в одну строку? место что ли экономите? крайне неприятно вычитывать.

сам код красивый)

[SAS888]

Сообщение от Dophin

а зачем Вы пишите код в одну строку? место что ли экономите? крайне неприятно вычитывать.

Во-первых, привычка. Во-вторых, в одну строку пишу те команды, которые могут быть объединены по какому-либо признаку. Например, определение диапазонов, присваивание значений переменным и т.п. Также, часто "укорачиваю" идущие подряд End If, Next, End With и т.п. Извиняюсь за предоставляемые неудобства. Учту на будущее.
А Вам бы я посоветовал брать код в тэги. Тоже, для удобочитаемости.

To Palantir:
Может Вам так нужно было? (см. вложение)

[Palantir]

Спасибо, уважаемый Dophin, огромное спасибо уважаемый SAS888! Воспользовался 1-м вариантом, именно он подошел идеально. А SAS888 сэкономил секретарше полдня рабочего времени, отчего ему за это дополнительное спасибо!

[SAS888]

А SAS888 сэкономил секретарше полдня рабочего времени...

Передавайте ей привет.