Поиск слова в строке

[Blind Guard]

Здраствуйте.

Программа следующая.
Пользователь вводит строку и слово из строки, но так как пользователи бывают пользователями, то "надо ж поэкспеременитровать"
В программе нужно проверить, есть ли в введённой строке введённое слово. При удачном исходе программа просто завершается, иначе выводит сообщение об ошибке. Уверен, что ошибка очень коварная, но всё же не могу её найти. Кто сможет найти буду благодарен.

.model small
.stack 100h
.data

    string_request db "Please, enter string:", 0Dh, 0Ah, '$'
    string_word_request db "Please, enter the word from string:", 0Dh, 0Ah, '$'
    warning_string db "Invalid Input! Try again:", 0Dh, 0Ah, '$'
    string db 200 dup('$')            
    string_word db 200 dup('$')      

.code        
start:

    mov ax, @data
    mov ds, ax
    
    mov dx, offset string_request
    mov ah, 9
    int 21h 
    
    mov ah, 0Ah
    mov dx, offset string
    int 21h 
    
    mov dx, offset string_word_request
    mov ah, 9
    int 21h     

    jmp q

string_word_warning:
    mov dx, offset warning_string
    mov ah, 9
    int 21h         
    
q: 
    mov ah, 0Ah
    mov dx, offset string_word
    int 21h    

    mov di, 2              ; string
    mov bp, 2              ; string_word 

    jmp start_check

probel_destroyer:    
    inc di

start_check:   
 
    cmp string[di], 031
    je probel_destroyer
        
x:   
    mov bl, string[di]         
    cmp string_word[bp], bl
    je good_symbol
    jmp bad_symbol
     
good_symbol:
    
    inc di
    inc bp
    cmp string_word[bp], 036
    je final_check
    jmp x

bad_symbol:
    cmp string_word[bp], 036
    je string_word_warning
    mov bp, 2
a:
    inc di
    cmp string[di], 031
    je probel_destroyer
    cmp string[di], 036
    je string_word_warning
    jmp a
    
final_check:
         
    cmp string[di], 031
    je win
    cmp string[di], 036
    je win
    jmp string_word_warning

win:     
int 20h   
end start

[vadimych]

Blind Guard, ошибка была далеко не одна.

.model small
.stack 100h
.data

    string_request db "Please, enter string:", 0Dh, 0Ah, '$'
    string_word_request db 0dh,0ah,"Please, enter the word from string:", 0Dh, 0Ah, '$'
    warning_string db 0dh,0ah,"Invalid Input! Try again:", 0Dh, 0Ah, '$'
    string db 254,256 dup (?)       
    string_word db 254,256 dup (?)        

.code        
start:

    mov ax, @data
    mov ds, ax
    
    mov dx, offset string_request
    mov ah, 9
    int 21h 
    
    mov ah, 0Ah
    mov dx, offset string
    int 21h 
    
    mov dx, offset string_word_request
    mov ah, 9
    int 21h     

    jmp q

string_word_warning:
    mov dx, offset warning_string
    mov ah, 9
    int 21h         
    
q: 
    mov ah, 0Ah
    mov dx, offset string_word
    int 21h    

    mov di, 2              ; string
    mov si, 2              ; string_word 


start_check:   
 
    cmp string[di],' '
    jne x
    inc di
    jmp start_check
        
x:   
    mov bl, string[di]         
    cmp string_word[si], bl
    jnz bad_symbol
     
good_symbol:
    
    inc di
    inc si
    cmp string_word[si],' '
    je final_check
    cmp string_word[si],0dh
    je final_check
    
    jmp x

bad_symbol:
    cmp string_word[si], 0dh
    je string_word_warning
    mov si, 2
a:
    inc di
    cmp string[di],' '
    je start_check
    cmp string[di], 0dh
    je string_word_warning
    jmp a
    
final_check:
         
    cmp string[di],' '
    je win
    cmp string[di], 0dh
    je win
    jmp string_word_warning

win:  
mov ax,4c00h   
int 21h   
end start

[Blind Guard]

Спасибо большое.
Не расчитывал на помощь

[Blind Guard]

Есть небольшой вопрос по вашему коду.
Зачем перед строками 0dh и 0ah?

    string_word_request db 0dh,0ah,"Please, enter the word from string:", 0Dh, 0Ah, '$'
    warning_string db 0dh,0ah,"Invalid Input! Try again:", 0Dh, 0Ah, '$'

[vadimych]

Чтобы вывод не затирал введённый текст, начинался с новой строки.

[Blind Guard]

Ясно, ещё раз спасибо.