Замена TXT1 на TXT2 в Selection при условии, что их (TXT2) там м.б. несколько

[DBEER]

Конкретней: есть фрагмент текста, где добрый Юзер настучал кучу пробелов между словами, пытаясь доступными ему средствами "украсить" форматирование. Надо в выделенном фрагменте заменить любое кол-во пробело, идущих сплошняком, на один. В Selection`е м.б. несколько таких мест. Самостоятельные поиски и найденное на этом форуме не дали должного эффекта. Одна из "Грабель" :

Range2.Find.Execute FindText:="  ", ReplaceWith:=" ", Replace:=wdReplaceAll

Приводит к замене не только в Selection`е, но и в последующем тексте, что не требуется.

[cw_o]

обрабатывайте Selection в цикле

Sub ReplaceSpaces()
    Dim Result As Boolean
    Result = True
    Do
        With Selection.Find
            .Text = "  "
            .Replacement.Text = " "
            .Forward = True
            .Wrap = wdFindContinue
            .Format = False
            .MatchCase = False
            .MatchWholeWord = False
            .MatchWildcards = False
            .MatchSoundsLike = False
            .MatchAllWordForms = False
        End With
        Result = Selection.Find.Execute(Replace:=wdReplaceAll)
    Loop Until Not Result
End Sub

[DBEER]

Спасибо за отклик, но не совсем то: те же грабли - сразу удаляются и все сдвоенные пробелы за пределами Selection`а. А там уже не надо - другая ситуация.
Selection выделенный текст, где (и только там) надо произвести замену.

[cw_o]

Прошу прощения, замените одну строчку

.Wrap = wdFindStop

[DBEER]

ОК!!! Заррааботалла!!!!
КОт Матроскин (С)

[Step_UA]

Можно без цикла

    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = " ( )@"
        .Replacement.Text = " "
        .Forward = True
        .Wrap = wdFindStop
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchAllWordForms = False
        .MatchSoundsLike = False
        .MatchWildcards = True
    End With
    Selection.Find.Execute Replace:=wdReplaceAll

[DBEER]

Спасибо, STEP_UA. А где почитать про правила пользования
Wildcards (сам язык - Wildcards-символы)??

[DBEER]

ВОт, например:
http://word.mvps.org/faqs/general/usingwildcards.htm
Но, хотелось бы, чего-нить канонического

[Step_UA]

чем не устраивает справка ворда?

[DBEER]

...что они в самом Ворде описаны (в хоорошем смысле этого слова). И даже по-русски.