DOS. Работа с клавиатурой не могу понять

[Alexis_777]

Здравствуйте, пытаюсь разобраться с буфером клавиатуры, прошу помочь объяснить некоторые моменты:
1. как работает процедура PrnHex, сам вникал, но так и не понял почему используются именно эти команды (особенно как работает команда das не могу понять почему вычитает именно 60 и 66)
2. также не могу понять эту часть кода: как наша клавиша загружается в ax (с прерыванием 16h и 0 функцией попроще (я вроде понял), а тут напрямую организована работа с буфером я понять не смог):

start:
;------ Очиcткa буфepa клавиатуры пepeд нaжaтием клaвиши --------------//
        push  ds  0                 ;
        pop   ds                    ;
        mov   al,byte[ds:41Ah]      ; выравниваем
        mov   byte[ds:41Ch],al      ;     ..голову и хвост буфера
 
;------ Пpoвepяeм нaличиe cимвoлa в буфepe ----------------------------//
sleep:  mov   ax,word[ds:41Ah]      ;
        mov   bx,word[ds:41Ch]      ;
        cmp   ax,bx                 ; голова равна хвосту?
        je    sleep                 ; да - циклимся..
 
;------ Читаем ASCII/SCAN нажатой клавиши -----------------------------//
        mov   si,ax                 ;
        add   si,400h               ; SI = адрес начала буфера
        lodsw                       ; берём от туда слово
        pop   ds                    ;
        cmp   al,13                 ; Enter --> выход!
        je    exit                  ;
        push  ax ax ax              ; запоминаем клавишу..

Прошу помочь объяснить или прокоментировать данные моменты, т.к. сам не могу понять((
Код взят мной с форума для ознакомления:

; fasm code.....
; Читает клавиши напрямую с буфера клавиатуры
org 100h
jmp start
 
mes0    db    13,10,' Symbol: $'
mes1    db    32,32,' Ascii: $'
mes2    db    32,32,' Scan: F0,$'
 
start:
;------ Очиcткa буфepa клавиатуры пepeд нaжaтием клaвиши --------------//
        push  ds  0                 ;
        pop   ds                    ;
        mov   al,byte[ds:41Ah]      ; выравниваем
        mov   byte[ds:41Ch],al      ;     ..голову и хвост буфера
 
;------ Пpoвepяeм нaличиe cимвoлa в буфepe ----------------------------//
sleep:  mov   ax,word[ds:41Ah]      ;
        mov   bx,word[ds:41Ch]      ;
        cmp   ax,bx                 ; голова равна хвосту?
        je    sleep                 ; да - циклимся..
 
;------ Читаем ASCII/SCAN нажатой клавиши -----------------------------//
        mov   si,ax                 ;
        add   si,400h               ; SI = адрес начала буфера
        lodsw                       ; берём от туда слово
        pop   ds                    ;
        cmp   al,13                 ; Enter --> выход!
        je    exit                  ;
        push  ax ax ax              ; запоминаем клавишу..
 
;------ Вывод данных на экран ------------------------------------------//
        mov   dx,mes0               ;
        call  Message               ;
        pop   ax                    ;
        int   29h                   ; выводим символ
 
        mov   dx,mes1               ;
        call  Message               ;
        pop   ax                    ;
        shl   ax,8
        call  PrnHex                ; выводим Ascii
 
        mov   dx,mes2               ;
        call  Message               ;
        pop   ax                    ;
        call  PrnHex                ; выводим Scan
 
        jmp   start                 ; читаем сл.клавишу..
exit:   int   20h                   ; на выход!
 
;нннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннн
Message:                            ; мессага DOS
        mov   ah,9                  ;
        int   21h                   ;
        ret                         ;
;------------------------------------------------------------------------
PrnHex: xchg  dx,ax                 ; вывод чисел в HEX
        mov   cx,2                  ; разрядов в числе (число в AH)
@@1:    shld  ax,dx,4               ;
        rol   dx,4                  ;
        and   ax,0Fh                ;
        cmp   al,0Ah                ;
        sbb   al,69h                ;
        das                         ;
        int   29h                   ;
        loop  @@1                   ;
        ret                         ;

[jillitil]

Сообщение от Alexis_777

... (особенно как работает команда das не могу понять почему вычитает именно 60 и 66)
2. также не могу понять эту часть кода: как наша клавиша загружается в ax (с прерыванием 16h и 0 функцией попроще (я вроде понял), а тут напрямую организована работа с буфером я понять не смог):

1. Откуда берутся 60 и 66 см. детально как работает инструкция ДАС (Десимал Аджюст афтэр Сабстракшн): https://www.felixcloutier.com/x86/DAS.html
2. Клавиатура аппаратно дёргает прерывание 9 оно же IRQ 1, вызывая обработчик БИОСа. Он в свою очередь опрашивает клавиатуру на предмет что изменилось/нажалось/отпустилось и записывает сканкод в кольцевой буфер на 16 символов, расположенный по адресу 40:1E, при этом обновляя указатель на голову. Когда вызываете прерывание 0х16 происходит считывание с кольцевого буфера и его обновление, а не опрос клавиатуры как можно предположить.
Т.о. ваша программа вместо корректного запроса у БИОСа что было нажато последовательно, в обход нагло считывает первый сканкод и удаляет всё остальное.

INT 9 - Keyboard Interrupt (Hardware Handler)
	related memory:
	40:17 = updates keyboard flag byte 0
	40:18 = updates keyboard flag byte 1
	40:1A = queue head ptr is set to buffer start if Ctrl-Break is hit
	40:1C = updates buffer tail pointer for each keystroke; sets
		queue tail ptr is set to queue start if Ctrl-Break is hit
	40:1E = updates keyboard buffer (32 bytes)
	40:71 = updates bit 7 of the BIOS break flag if Ctrl-Break is hit
	40:72 = updates reset flag with 1234H if Ctrl-Alt-Del pressed
	40:96 = indicates keyboard type (AT,PS/2)
	40:97 = updates keyboard LED flags (AT,PS/2)
	FFFF:0 = reboot code called if Ctrl-Alt-Del pressed

	related interrupts:

	INT 5     invoked if print screen key pressed
	INT 1B    invoked if Ctrl-Break key sequence pressed
	INT 15,85 invoked on AT if system request key is pressed
	INT 15,4F invoked on machines after PC/AT with AL = scan code


	- records key press and key release via IRQ1/8259 and
	  stores scan codes in the BIOS buffer located at 40:1C
	- keyboard controllers also buffer data when interrupts are
	  disabled at the 8259 interrupt controller
	- keyboard controller is capable of storing 16 keystrokes
	  even when interrupts are disabled at the 8259
	- normal INT 9 execution takes approximately 500 microseconds;
	  at least one standard XT BIOS is known to take up to 1.3
	  milliseconds to execute

[R71MT]

Сообщение от Alexis_777

особенно как работает команда das не могу понять почему вычитает именно 60 и 66

псевдо-код инструкции DAS гласит:

• если AL > 99h, или флаг(CF) стал =1,
  то сделать AL = (AL-60h);

• если AL > 09h, или флаг(AF) стал =1,
  то сделать AL = (AL-06h)

-- CF взводится в том случае,
когда ст.бит перейдёт из AL в AH (переполнение AL = 1.0000.0000).
-- AF взводится в том случае,
когда из мл.тетрады AL, бит переходит в ст.тетраду AL (0001.0000).

Теперь, смотрим на код процедуры "PrnHex"..
Здесь инструкцией SBB мы принудительно от тетрады(AL) отнимаем байт(69h).
Значит по псевдо-коду, DAS всегда будет отнимать от AL 60h, т.к. AL всегда будет >99h.
При этом по флагам будет вычитаться ещё и CF и 06h.

Пример: AL = 03h
        --------
        sbb  al,69h = (03h-69h) = 9Ah-01h(CF) = 99h
        das         = (99h-60h) = 39h-06h = 33h = ascii-код тройки

Пример: AL = 0Ah
        --------
        sbb  al,69h = (0Ah-69h) = A1h
        das         = (A1h-60h) = 41h = ascii-код символа(A)

Сообщение от Alexis_777

как наша клавиша загружается в ax

Клавиатурный буфер может хранить коды последних 16-ти клавиш, в формате ascii/scan - итого 32 байта. Зная его адрес, можно читать инфу прямо из этого буфера. Здесь я приводил его описание: http://www.programmersforum.ru/showt...36#post1752436

[Alexis_777]

R71MT, Спасибо) Очень помогли разобрался с das)) Просто не сразу понял что по умолчанию 60 отнимается)) Из-за этого запутался))

[Alexis_777]

Может кто-нибудь сможет объяснить как работает данная конструкция)) А то я не могу понять этого (наверное, слишком сложно для меня):

mov   si,ax                 ;
        add   si,400h               ; SI = адрес начала буфера
        lodsw                       ; берём от туда слово
        pop   ds

Просто этот пример более наглядный) Я сначала делал с прерыванием 16h и 0 функцией) Там всё просто, но не наглядно)

[R71MT]

это/всё для LODSW, который читает в AX из DS:SI
чтобы получить в SI указатель на начало буфера, сначала в AX берётся смещение с адреса 1Ah (внутри буфера), а потом к нему прибавляется база 400h.

кстати один-и-тотже адрес, можно указывать двумя способами, т.е. вот эти 2 адреса одинаковы: 0040:001Ah и 0000:041Ah - в коде выше приводится второй вариант.

[Nif-naf]

Bce mak u cmpoku y4u