tasm, использование команд ввода/вывода. Доступ к портам

[iggor]

Помогите как сделать ввод с клавиатуры двух чисел и их сумму, а ответ чтоб выводило в рамку...??

начальный код:
.model small
.stack 256
.data
message db 25 dup (7)
db 80*12 dup (' ')
db 35 dup (' '),201,9 dup (205),187,10,13
db 35 dup (' '),186,'otvet',186,10,13
db 35 dup (' '),200,9 dup (205),188,10,13
db 10*80 dup (' '),'$'
.code
begin:
mov ax,@data
mov ds,ax
mov ah,9
mov dx, offset message
int 21h
mov ah,1
int 21h
mov ax,4c00h
int 21h
end begin

[MalCer]

Всё что тебе нужно было это перевести строку в число. Алгоритмов в интернете навалом!!! Ответ с рамкой сам надеюсь добьешь! К тому же сверхсложного здесь нет. Сумма 2-х чисел:

CSEG segment
assume cs:CSEG, ds:CSEG, es:CSEG, ss:CSEG
org 100h
start:

  mov ax,3
  int 10h
  mov si,10
  call isEnter
  push di
  call isEnter
  pop ax
  add ax,di
  push ax

  mov ah,9
  mov dx,offset dbResult
  int 21h

  pop ax
  xor cx,cx

isDiv:  xor dx,dx
  div si
  push dx
  inc cx
  or ax,ax
  jnz isDiv

isOut:  pop ax

  or al,30h
  int 29h
  loop isOut
  xor ax,ax
  int 16h
  ret
;
dbResult db 13,10,'Resultat:$'
dbEnter  db 13,10,'vvod chisla '
dbVal  db 'W:$'

isEnter: inc byte ptr[dbVal]

  mov ah,09
  mov dx,offset dbEnter
  int 21h

  xor di,di

noNumber: xor ax,ax
  int 16h
  cmp al,13
  jz isStop
  cmp al,'0'
  jb noNumber
  cmp al,'9'
  ja noNumber
  int 29h
  and ax,0fh
  xchg ax,di
  xor dx,dx
  mul si
  add di,ax
  jmp short noNumber
isStop:  ret
 CSEG ends
end start