API Функция

[Horus92]

Не могу реализовать функцию FlashWindow
вот мой код

.586
 .model flat,stdcall
 
FlashWindow PROTO      ,:DWORD, :DWORD, :DWORD
option casemap:none


includelib user32.lib
invoke FlashWindow, hWnd, offset bInvert, 2d, NULL

не работает почему??

[airyashov]

у функции 2-а параметра
FlashWindow(Wnd: HWnd; Invert: Bool)

[Horus92]

а как вывисти незнаю !
немоглибы вы помоч мне с выводом с помошью инвок

[Stilet]

вывисти

Вывести

не работает почему??

А это что и весь код?
Как уже сказали выше invoke FlashWindow, hWnd, true

[yuran666666]

; а почему бы и не вот так?

	.386
	.model flat,stdcall
	option casemap:none
	include \masm32\include\windows.inc
	include \masm32\include\user32.inc
	include \masm32\include\kernel32.inc
	include \masm32\include\gdi32.inc
	include \masm32\include\comdlg32.inc
	include \masm32\include\shell32.inc
	includelib \masm32\lib\user32.lib
	includelib \masm32\lib\kernel32.lib
	includelib \masm32\lib\gdi32.lib
	includelib \masm32\lib\comdlg32.lib
	includelib \masm32\lib\shell32.lib
WinMain proto :DWORD,:DWORD,:DWORD,:DWORD
.const
IDC_TIMER		equ 1
.data?
hInstance		HINSTANCE ?
CommandLine		LPSTR ?
TimerID 		dd ?
.data
ClassName 		db "FlashWind"
FormCaption		db "Form",0
.code
start:
	invoke	GetModuleHandle,NULL
	mov		hInstance,eax
	invoke	GetCommandLine
	invoke	WinMain,hInstance,NULL,CommandLine,SW_SHOWDEFAULT
	invoke	ExitProcess,eax
WinMain proc hInst:HINSTANCE,hPrevInst:HINSTANCE,CmdLine:LPSTR,CmdShow:DWORD
LOCAL wc	:WNDCLASSEX
LOCAL msg 	:MSG
LOCAL hwnd	:HWND
	mov		wc.cbSize,SIZEOF WNDCLASSEX
	mov		wc.style,CS_BYTEALIGNCLIENT
	mov		wc.lpfnWndProc,offset WndProc
	mov		wc.cbClsExtra,NULL
	mov		wc.cbWndExtra,NULL
	push	hInst
	pop		wc.hInstance
	mov		wc.hbrBackground,COLOR_BTNFACE+1
	mov		wc.lpszClassName,OFFSET ClassName
	invoke	LoadIcon,NULL,IDI_APPLICATION
	mov		wc.hIcon,eax
	mov		wc.hIconSm,eax
	invoke	LoadCursor,NULL,IDC_ARROW
	mov		wc.hCursor,eax
	invoke	RegisterClassEx,addr wc
invoke CreateWindowEx,0,ADDR ClassName,ADDR FormCaption,WS_SYSMENU or WS_SIZEBOX,648,84,384,291,0,0,hInst,0
	mov		hwnd,eax
	INVOKE	ShowWindow,hwnd,SW_SHOWNORMAL
	INVOKE	UpdateWindow,hwnd
	

	.WHILE TRUE
		invoke	GetMessage,ADDR msg,0,0,0

		.BREAK .IF (!eax)
		invoke	TranslateMessage,ADDR msg
		invoke	DispatchMessage,ADDR msg
	.ENDW
 	mov	eax,msg.wParam
	ret
WinMain endp


WndProc proc hWnd:HWND,uMsg:UINT,wParam:WPARAM,lParam:LPARAM
	.IF uMsg == WM_DESTROY
		invoke KillTimer,hWnd,TimerID
		invoke	PostQuitMessage,NULL
;#############################################################
				
	.elseif uMsg == WM_TIMER
			invoke FlashWindow, hWnd, TRUE
			invoke Sleep,300
			invoke FlashWindow, hWnd, FALSE
			
;#############################################################		
	.ELSEIF uMsg == WM_CREATE
			invoke SetTimer,hWnd,IDC_TIMER,300,NULL
			
			mov TimerID,eax
	.ELSE
		invoke	DefWindowProc,hWnd,uMsg,wParam,lParam
		ret
	.ENDIF
	xor		eax,eax
	ret
WndProc endp
end start