Word VBA как вставить разрыв принудительный в формулу ?

[Вождь]

Просто замените слово Selection на Ваш Range.

Описали бы задачу в целом. Что есть на входе? Что должно быть на выходе?
А то уже получили кучу ответов на общие отстраненные вопросы, а толку как я понял мало.

[bdfy]

выдрал кусочек кода

text = " G_Ст="
text = text & "((" & ChrW(960) & "·D_a^2/4-" & ChrW(960) & "·D^2/4-D·S'_п·10^-6)+$" '& ChrW(2177)
text = text & "(" & ChrW(960) & "·D^2/4-Z_2·S'_п·10^-6))·l_" & ChrW(948) & "·" & ChrW(961) & "_ст" & "="

Set oRng = oDoc.Paragraphs(oDoc.Paragraphs.Count).Range
  With oRng
         'вставка формулы
        .text = text
        Set oRng = oRng.OMaths.Add(oRng)
        
        oRng.Font.Italic = False
        Set objEq = oRng.OMaths(1)
        objEq.buildup
       
  End With

oDoc некий документ Word в данном случае.
я знаю что на место $ надо бы вставить разрыв - иначе переносы будут не очень корректные. как это сделать ?

[Вождь]

Решение прояснилось.

Команда Breaks.Add работает только перед оператором. А вот как она сработает, это задает параметр Document.OMathBreakBin:
wdOMathBreakBinBefore - оставить оператор после разрыва
wdOMathBreakBinAfter - поместить оператор перед разрывом
wdOMathBreakBinRepeat - дублировать оператор (до и после разрыва)
Также заметил, что форматирование формулы (.Italic = False) удаляет разрывы.

Переставил "$" вперед операторов и добавил вышеупомянутый параметр:

Dim oDoc As Word.Document
Dim oRng As Word.Range
Dim objEq As Word.OMath
Dim Text$

    Set oDoc = ActiveDocument
    ' текст формулы
    Text = " G_Ст="
    Text = Text & "((" & ChrW(960) & "•D_a^2/4-" & ChrW(960) & "•D^2/4-D•S'_п•10^-6)$+" '& ChrW(2177)
    Text = Text & "(" & ChrW(960) & "•D^2/4-Z_2•S'_п•10^-6))•l_" & ChrW(948) & "•" & ChrW(961) & "_ст" & "="
    ' вставка формулы
    Set oRng = oDoc.Paragraphs.Last.Range
    oRng.Text = Text
    Set oRng = oRng.OMaths.Add(oRng)
    oRng.Font.Italic = False
    ' форматирование формулы
    Set objEq = oRng.OMaths(1)
    oDoc.OMathBreakBin = wdOMathBreakBinAfter
    Do While oRng.MoveStartUntil("$", oRng.Characters.Count) > 0
        With oRng.Characters.First
            .Delete
            objEq.Breaks.Add .Duplicate
        End With
    Loop
    objEq.BuildUp

[bdfy]

вот теперь спасибо разобрался работает

А вот как она сработает, это задает параметр Document.OMathBreakBin:

это собственно как правило для документа задается. в меню конструктора формулы. так что в код это пихать имхо излишне.