EXE MASM,ошибки при компиляции

[laim]

Изначально программа была в Сом формате, при компиляции в ехе возникают ошибки
3.asm(60) : error A2206: missing operator in expression
3.asm(89) : error A2206: missing operator in expression

title Запись чисел ехе файл

        .Model  small
        .Code
        ORG     100h     ; резервирование памяти для
                         ; префикса программного сегмента (PSP)
Start:  jmp     SHORT main     ; обход данных и экономия 1 байт
; ----------------- ДАННЫЕ ------------------------------------------
; !!!!! сегментов ДАННЫХ, СТЕКА, ДОПОЛНИТЕЛЬНОГО НЕТ !!!!!!!
CR_LF   db      0dh,0ah,'$'
L       dw      6
Number  dw      12345
inv     db      'Демонстрация вывода чисeл: $'
OutBuf  db      11 dup(?),'$'   ; Буфер вывода   
; -------------------------------------------------------------------

main    proc    NEAR        ; ТОЛЬКО NEAR !!!! Иначе зависание
        lea     dx,inv
        call    output      ; вывод строки inv
	    Lea     bx,OutBuf      ; адрес буфера вывода
        Mov     ax,Number
	    CALL    Bin_ASCII      ; Binary ---> ASCII
	    Lea     dx,[bx]
        call    output          ; вывод ПОЛОЖИТЕЛЬНОГО числа
        Mov     ax, -157
        CALL    Bin_ASCII      ; Binary ---> ASCII
	    Lea     dx,[bx]
        call    output          ; вывод ОТРИЦАТЕЛЬНОГО числа
        lea	    dx, CR_LF
        call    output          ; переход на след. строку
        ret                 ; IRET - зависание!!!
main    endp

; ---------- вывод строки -------------------------------------------
; ВХОД:
;    DX- начальный адрес строки. 
;               Символ окончания строки '$'.
; ВЫХОД:
;    НЕТ
;--------------------------------------------------------------------
output  proc
        push    ax
	    mov	ah,9
	    int	21h
        pop     ax
	    ret
output	endp

;---------- Procedure Bin_Ascii ----------------------------
; ВХОД:
;     число -------> AX
;     нач. адрес буфера вывода ------> BX
;     длина буфера вывода ------> L
; ВЫХОД:
;       строка цифр в виде -ЦЦЦЦЦ или ЦЦЦЦЦЦ
;       нач. адрес буфера вывода ------> BX
;       факт. длина буфера вывода ------> CX <= L
;----------------------------------------------------------
Bin_Ascii  Proc     Near
            Push    dx si ax
            Mov     cx,L
 
 Fill_Buf:                           ; очистка буфера вывода 
            Mov     Byte ptr [bx],' '
            Inc     bx               ; и установка ВX на конец буфера
            Loop    Fill_Buf
            
            Mov     si,10
            Or      ax,ax           ; число ОТРИЦАТЕЛЬНОЕ?
            Jns     Clr_Dvd         ; НЕТ, обход
            Neg     ax              ; ДА - меняем знак
 Clr_Dvd:
            Xor     dx,dx
            Div     si              ; <DX:AX> = <DX:AX>/10
            Add     dx,'0'          ; остаток -----> ASCII
            Dec     bx
            Mov     Byte PTR [bx],dl ; символ -----> буфер
            Inc     cx               ; кол-во символов
            Or      ax,ax            ; частное = 0 ?
            Jnz     Clr_Dvd          ; НЕТ - продолжаем вычисления
            
            Pop     ax               ; выгружаем  из стека исх. число
            Or      ax,ax            ; оно ОТРИЦАТЕЛЬНОЕ ?
            Jns     NoMore           ; НЕТ, обход
            Dec     bx
            Mov     Byte ptr [bx],'-' ; добавляем знак '-'
            Inc     cx
 NoMore:
            Pop     si dx
            Ret
Bin_Ascii  Endp

        end     start          ; указание точки входа ОБЯЗАТЕЛЬНО!!!

сорец прилагаю.

[Ulex]

3.asm(60) : error A2206: missing operator in expression

В скобочках написан номер строки, где произошла ошибка.

[laim]

ошибки выбивает в етих строках Push dx si ax
Pop si dx
я хз что добавить

[veniside]

вероятно, нужно вместо

Push    dx si ax

нарисовать

Push    dx
push si
push ax

а вместо

Pop si dx

развернуть

Pop si
pop dx

[laim]

Сообщение от veniside

вероятно, нужно вместо

Push    dx si ax

нарисовать

Push    dx
push si
push ax

а вместо

Pop si dx

развернуть

Pop si
pop dx

спс, ошибки пропали
теперь при запуске проги пишет
Процессор NTVDM обнаружил недопустимую инструкцию
скрины прилагаю

[Mikl___]

laim
1) в функцию main первыми строчками вставь mov ax,@data/mov ds,ax
2) строчку ORG 100h убери это же не СОМ, а ЕХЕ!
3) Данные должны быть в сегменте data, команды в сегменте code,
4) start: jmp main убери
5) вместо RET в main proc напиши mov ah,4Ch/ int 21h
6) в конце программы напиши end main вместо end start

[laim]

Сообщение от Mikl___

laim
1) в функцию main первыми строчками вставь mov ax,@data/mov ds,ax
2) строчку ORG 100h убери это же не СОМ, а ЕХЕ!
3) Данные должны быть в сегменте data, команды в сегменте code,
4) start: jmp main убери
5) вместо RET в main proc напиши mov ah,4Ch/ int 21h
6) в конце программы напиши end main вместо end start

большое спасибо, поправил теперь работает