Самый быстрый режим работы процессора

[f.hump]

таки, да, не скомпилится.

по теме:
начинаю подозревать, что самый быстрый режим работы процессора - 64-х битный.
16 регистров общего назначения, 16 xmm/ymm, native 64 арифметика, 64-битная адресация (винда, конечно, только 8Тб разрешает адресовать, но и это я думаю не мало).

[Пепел Феникса]

начинаю подозревать, что самый быстрый режим работы процессора - 64-х битный.
16 регистров общего назначения, 16 xmm/ymm, native 64 арифметика, 64-битная адресация (винда, конечно, только 8Тб разрешает адресовать, но и это я думаю не мало).

ну про винду речь не идет, так как там потери на нужды системы.
да и 8ТБ то вирт памяти, физических объемов то еще нет таких.
а вообще, вы правы.

кстати, насчет работает надо смотреть в офф документации.

[Goodwin98]

даже нинаю... а почему никто не потестит хотя бы в вирт машине работают команды или проц перезагружается ?(

[Пепел Феникса]

это как?

мы программисты, а не тестеры, нам надо спорить, пробовать неинтересно

[JTG]

Ну вот можно страшнообраз дискеты собрать в FASM
Считалка длины строки с буфером 8 байт с MMX на голом железе прекрасно работает.

format binary as 'img'
org 7C00h
start:
        jmp     short boot
        nop

b08_OEM         db 'LOL_BOOT'
wSecSize        dw 512
bSecsPerCluster db 1
wResSecs        dw 1
bNumFATs        db 2
wRootEntries    dw 224
wTotSecs        dw 2880
bMedia          db 0F0h
wSecsPerFAT     dw 9
wSecsPerTrack   dw 18
wHeads          dw 2
dHiddenSecs     dd 0
dBigTotSecs     dd 0
bDrive          db 0
unused          db 0
bExtBootSig     db 29h
dSerNum         dd 0FFFFFFFFh
b11_VolumeLabel db 11 dup ('X')
b08_FileSysID   db 'FAT12   '

; boot sector

boot:
use16
        xor     ax, ax
        mov     ds, ax

        mov     esi, string
        call    MMX_Find_String_Length
        mov     eax, ecx
        mov     ebx, 10d
        mov     edi, buffer
        call    IntToStr
        mov     esi, length
        call    Write_String
        mov     esi, buffer
        call    Write_String
        jmp     $

; esi <- 8 byte aligned string
; ecx -> length in bytes
align 8
MMX_Find_String_Length:
        push    eax
        push    ebx
        push    esi
        mov     ebx, temp_qword
        pxor    mm1, mm1
        xor     ecx, ecx

.compare_loop:
        movq    mm2, qword[esi]
        pcmpeqb mm2, mm1
        movq    qword[ebx], mm2
        cmp     dword[ebx], 0
        jnz     .first_dword_has_a_hit
        cmp     dword[ebx+4],0
        jnz     .second_dword_has_a_hit

        add     ecx, 8
        add     esi, 8
        jmp     .compare_loop

.second_dword_has_a_hit:
        add     ecx, 4
        mov     eax, [ebx+4]
        jmp     .start_byte_testing

.first_dword_has_a_hit:
        mov     eax, [ebx]

.start_byte_testing:
        mov     edx, eax
        and     edx, 0x000000ff
        jnz     .done
        inc     ecx
        mov     edx, eax
        and     edx, 0x0000ff00
        jnz     .done
        inc     ecx
        mov     edx, eax
        and     edx, 0x00ff0000
        jnz     .done
        inc     ecx
        mov     edx, eax
        and     edx, 0xff000000

.done:
        pop     esi
        pop     ebx
        pop     eax
        ret
align 8
        temp_qword  dq 0

IntToStr:
;  eax <- number
;  ebx <- base
;  edi <-> buffer
        xor  ecx, ecx
.new:
        xor  edx, edx
        div  ebx
        push edx
        inc  ecx
        and  eax, eax
        jnz  .new
.loop:
        pop  eax
        add  al, 30h
        cmp  al, '9'
        jng  .ok
        add  al, 7
.ok:
        stosb
        loop .loop
        ret

Write_String:
; DS:SI <- string
        mov  ah, 0xE
        xor  bh, bh
        mov  bl, 0x7
.nextchar:
        lodsb           
        or  al,al
        jz  .return
        int  10h
        jmp .nextchar
.return:
        ret

        string      db 'Hi guys, you know we are always trying to find the best routines to optimize.', 0
        length      db 'Length: ', 0
        buffer      db '   bytes',0

rb 7C00h + 512 - 2 - $
db 055h, 0AAh

; FAT1, FAT2
db 0F0h, 0FFh, 0FFh
db 11FDh dup (0)
db 0F0h, 0FFh, 0FFh
db 11FDh dup (0)

; Root directory
db 1C00h dup (0)

; Free space
db 163E00h dup (0F6h)

[Пепел Феникса]

b08_OEM         db 'LOL_BOOT'

format binary as 'img'

а as тут это задание расширения по умолчанию?

[JTG]

угу_______

[Tronix]

Ну я же говорил. А f.hump нам тут какие-то сказки про инициализацию досом процессора рассказывал и тд. Конечно все команды расширения процессора работают под голым реалмодом, без всяких там инициализаций. ЧТД, как говорица.

[rpy3uH]

Сообщение от f.hump

по теме:
начинаю подозревать, что самый быстрый режим работы процессора - 64-х битный.
16 регистров общего назначения, 16 xmm/ymm, native 64 арифметика, 64-битная адресация (винда, конечно, только 8Тб разрешает адресовать, но и это я думаю не мало).

64-х битный режим точно не претендует на звание самого быстрого режима.
либо реальный либо защищённый. тут надо тесты проводить

[Пепел Феникса]

rpy3uH, он действительно самый быстрый, если конечно работать в этом режиме с rax, а не eax.
а если работать в 64-битах, как в 32-ух, то разницы скорее всего и не будет вовсе.
(кстати насколько я помню, 64-ех битный режим, не может быть не защищенным, или не помню уже)