Как в DOS принято вызывать процедуры

[Namolem]

Очень мусорный код, хочу немного распутать. Как в DOS'e принято делать процедуры/функции для:

void func(int a,int b);

void func(void);

int func(int a,int b);

?

Как обычно передаются/возвращаются данные? Через регистры, стек, еще как-то? Интересует компактный вид

Компилятор TASM

[rpy3uH]

вообще? если вообще, то как хочешь. эти соглашения в DOS никому не нужны.

DOS давно пора уже забыть. DOS изучают разве что в универах, да и то не всегда...
собственно и TASM тоже пора уже на помойку выкинуть! он устарел по всем параметрам

[Пепел Феникса]

Как обычно передаются/возвращаются данные? Через регистры, стек, еще как-то? Интересует компактный вид

если именно про те примеры, то ответа нет, ибо не указали соглашение о вызове.

возврат в регистре rax/eax/ax

[Son Of Pain]

Там тоже разные соглашения вызовов были, как и в windows. У cdecl и pascal ноги оттуда растут, в частности.
Потому действительно, если никаких других ограничений нет - можно выбирать любое соглашение.

[Mikl___]

Namolem
Это не зависит ни от DOS'а ни от Windows. Это особенность синтаксиса конкретного ассемблера. Например, для TASM и MASM: при передаче аргументов через стек командой PUSH можно пренебречь.
Расширенный синтаксис инструкции CALL в TASM:
CALL имя_процедуры [язык] [, аргументы]
Параметр команды CALL «язык» определяет способ передачи аргументов процедуре и способ очистки стека от переданных аргументов. В качестве «языка» допускается применение ключевых слов: C, CPP, PASCAL, BASIC, PROLOG или NOLANGUAGE. Если тип языковых соглашений не задан, то используется тип, указанный в директиве MODEL или явное указание типа языковых соглашений в объявлениях PROC или PUBLIC перекрывает для данного идентификатора тип, назначенный директивой MODEL. В языках PASCAL, BASIC и PROLOG аргументы процедуры будут переданы в стек в том же порядке, в котором они указываются в операторе вызова процедуры, а в языках C/C++ используется обратный порядок.
Языковые соглашения определяют порядок очистки стека от переданных аргументов. В языках C/C++ это возлагается на вызывающую процедуру, а во всех остальных на вызываемую. Следующая программа, написанная под TASM, вызывает одну и туже процедуру t1 с параметром PASCAL и C.
Процедура t1 закончена директивой RET, а компилятор, в зависимости от языкового соглашения, сам подставит RETN/F или RETN/F число

.386
.model flat
.code
start: call t1 PASCAL,1,2,3 ;вызываем t1(1,2,3) по 
; соглашению о стиле вызова функций как в языке PASCAL
call t1 C,1,2,3;вызываем t1(1,2,3) по соглашению о стиле
; вызова функций как в языке C/С++
retn; выход из программы
t1 proc; описание процедуры t1
ret; выход из подпрограммы
t1 endp
end start

Будет скомпилирована в следующую последовательность команд:

push 1
push 2
push 3
call 4010A1h
push 3
push 2
push 1
call 4010A1h
add esp,12; очистка стека от 12 байт (в исходном тексте отсутствует)
retn
4010A1h: retn

Видно, что в зависимости от параметра PASCAL или C, изменился порядок следования аргументов процедуры t1, а после call t1 C,1,2,3 появилась инструкция add esp,12, которой не было в первоначальном тексте.
MASM не позволяет записать аргументы CALL через запятую – для этого в MASM есть директива INVOKE. Для использования INVOKE требуется первоначально определить прототип процедуры, то есть указать количество аргументов и их тип:
имя_ процедуры PROTO [расстояние] [язык] [, [параметр]:тип]...
Скомпилированные программы будут отличаться в зависимости от параметров директивы model, proto, proc или от ключей, использованных при компиляции (/Gc или /Gd). Следующая программа использует соглашение о стиле вызова функций как в FORTRAN или в PASCAL:

.386
.model flat 
.code
t1 PROTO pascal,:DWORD,:DWORD,:DWORD; прототип процедуры t1
start:  invoke t1, 1, 2, 3
retn; выход из программы
t1 proc pascal, a:DWORD,b:DWORD,d:DWORD; описание процедуры t1
ret; выход из подпрограммы
t1 endp
end start

Эта программа компилируется в следующую последовательность
команд:

push 1
push 2
push 3
call 4000D0h
retn; выход из программы
4000D0: retn 0Ch; очистка стека от аргументов будет сделана t1

А эта программа использует соглашение о стиле вызова функций как C/C++ в директиве model:

.386
.model flat, c
.code
t1 PROTO :DWORD,:DWORD,:DWORD
start:  invoke t1, 1, 2, 3
retn
t1 proc a:DWORD,b:DWORD,d:DWORD
; функции будет передано три аргумента a, b и d
ret
t1 endp
end start

и компилируется в в следующую последовательность команд:

push 3
push 2
push 1
call 4000D3h
add esp,0Ch
; очистка стека от аргументов будет сделана основной программой
retn; выход из программы
4000D3: retn; выход из подпрограммы без очистки от аргументов