Сравнение и сортировака двух и более столбцов данных (макрос)

[Hugo121]

Ну так я же сказал - смотрите по месту. Неужели совсем код не читаете?
Если не надо суммировать первый столбец - значит типа так:

            For i = 1 To UBound(b)
                If .exists(b(i, 1)) Then
                    t = .Item(b(i, 1))
                    c(t, 1) = b(i, 1)
                    For x = 2 To 3: c(t, x) = c(t, x) + b(i, x): Next
                End If
            Next

Ничего в логике не поменялось.

[gladius13]

Сообщение от Hugo121

Ну так я же сказал - смотрите по месту. Неужели совсем код не читаете?

К сожалению нет, в программировании я 0 без палочки, обычный средний пользователь Excel, поэтому то и достаю Вас . Спасибо, что помогаете.

Сообщение от Hugo121

Если не надо суммировать первый столбец - значит типа так:

            For i = 1 To UBound(b)
                If .exists(b(i, 1)) Then
                    t = .Item(b(i, 1))
                    c(t, 1) = b(i, 1)
                    For x = 2 To 3: c(t, x) = c(t, x) + b(i, x): Next
                End If
            Next

Ничего в логике не поменялось.

Сейчас макрос выставляет значения только двух смежных столбцов, а основной столбец с совпадающими значениями остается пустым.

[Hugo121]

Думаю, пора уже актуализировать файл и код - а то может мы о разном говорим
Покажите пример данных/файл и код, и что где не работает.

[gladius13]

Сообщение от Hugo121

Думаю, пора уже актуализировать файл и код - а то может мы о разном говорим
Покажите пример данных/файл и код, и что где не работает.

Ох, простите, видимо я погорячился, макрос вроде бы сейчас работает как надо. Единственное, чего не хватает - большего количества столбцов, которые выстраиваеются вместе со сравниваемым столбцом. Вы об этом писали выше, но у меня так и не получилось увеличить их количесво.
Приложил условный пример.
Сейчас совпадающие данные из столбца B вместе с данными из столбцов С и В выстраиваются напротив соответсвующих значенийй в столбцах F G H. Хотелось бы добавить еще два смежных столбца к столбцу B (E и F)(всего получится 4), а результат чтобы выстраивался например в столбце H и последующих столбцах.

[Hugo121]

"Хотелось бы добавить еще два смежных столбца к столбцу B (E и F)"
ну так добавьте - вместо
b = Range(.[D1], .Range("B" & iLastrow)).Value
пишем
b = Range(.[F1], .Range("B" & iLastrow)).Value

"(всего получится 4)" - вместо
ReDim c(1 To UBound(a), 1 To 3)
пишем
ReDim c(1 To UBound(a), 1 To 5)
и вместо
For x = 2 To 3
пишем
For x = 2 To 5
ну и выгрузка "а результат чтобы выстраивался например в столбце H":
.[H1].Resize(UBound(c), 5) = c

Итого:

Option Explicit


Sub compare()
    Dim a(), b(), c(), t&, x As Byte, iLastrow As Long, i As Long

    With Sheets(1)
        iLastrow = .Cells(Rows.Count, 1).End(xlUp).Row
        a = Range(.[A1], .Range("A" & iLastrow)).Value
        iLastrow = .Cells(Rows.Count, 2).End(xlUp).Row
        b = Range(.[F1], .Range("B" & iLastrow)).Value

        ReDim c(1 To UBound(a), 1 To 5)

        With CreateObject("Scripting.Dictionary")

            For i = 1 To UBound(a)
                .Item(a(i, 1)) = i
            Next

            For i = 1 To UBound(b)
                If .exists(b(i, 1)) Then
                    t = .Item(b(i, 1))
                    c(t, 1) = b(i, 1)
                    For x = 2 To 5: c(t, x) = c(t, x) + b(i, x): Next
                End If
            Next
        End With

        .[H1].Resize(UBound(c), 5) = c
        .Activate
    End With

End Sub

Как видно, вместо 5 можно использовать например переменную.
Т.е. в начале спросить у юзера - сколько столбцов желаете?
Затем это число использовать в коде, только место выгрузки тоже соответственно скорректировать, а лучше вообще выгружать в новый файл.
Как вариант.