Переполнение деления и число 2559

[Teor]

Всем привет. Нужна небольшая помощь в такой программе:

.model small
.stack 100h
.data
ErrMess db 'Число макс. 2559!',0dh,0ah,'$'
NUMBER dw 2558
Ten db 10
.code
PRINTNUM proc
mov cx,0
repeat:
cmp ax,2559
jg ErrExit
div [ten]
mov dx,0
mov dl,al
mov al,ah
add al,'0'
mov ah,0
push ax
mov ax,dx
inc cx
cmp ax,0
je PRINTDIGITS
jmp repeat
PRINTDIGITS:
mov ah,2
pop dx
int 21h
loop PRINTDIGITS
jmp MOUT
ErrExit:
mov ah,9
mov dx, offset ErrMess
int 21h
MOUT:
ret 
PRINTNUM endp
StartProg:
mov ax,@data
mov ds,ax
mov ax,[Number]
Call PRINTNUM
mov ah,8
int 21h
mov ah,4ch
int 21h
end StartProg

Данная программа выводит на экран число Number, которое сейчас равняется 2558. Собственно вопрос в том, почему числа более чем 2559 не выводятся на экран, а именно выскакивает сообщение "Переполнение деления". Как я понял это зависит от числа на которое делим, но что конкретно происходит понять не могу. Может кто-то знает в чем фишка?

[Ulex]

Так как делителем является переменная размерностью байт (Ten db 10), то результат от деления размещается в регистре al, а остаток в ah (это 8-ми битные части регистра eax). Ну а так как результат от деления 2560 на 10 составляет 256 и его невозможно разместить в регистре al, то и возникает ошибка "Переполнение деления".

[alexcoder]

Потому что при делении 16-разрядного числа на 8-разрядное результат помещается в 8-разрядный регистр al. 2600/10=260 уже не вмещается в al, вот и происходит ошибка деления. Выход делить DX:AX на 10 как шестнадцатиразрядное число.

[Ulex]

Вот оно:

.model small
.stack 100h
.data
NUMBER dw 65010
Ten dw 10
.code
PRINTNUM proc
mov cx,0
repeat:
xor dx,dx
div [ten]
add dx,'0'
push dx
inc cx
cmp ax,0
je PRINTDIGITS
jmp repeat
PRINTDIGITS:
mov ah,2
pop dx
int 21h
loop PRINTDIGITS
ret 
PRINTNUM endp
StartProg:
mov ax,@data
mov ds,ax
mov ax,[Number]
Call PRINTNUM
mov ah,8
int 21h
mov ah,4ch
int 21h
end StartProg

[Mikl___]

Teor
данная программа позволит делить числа от 65535 до 0 на 10 -- здесь деление заменено на умножение, а результат всегда в регистре DX

; masm dos exe #
.286
.model small
.data
X dw 0FFFFh
result dw ?
.code
start:	mov ax,@data
	mov ds,ax
	mov ax,52429; "волшебное число"
	mul X
	shr dx,3
	mov result,dx; result:= X/10     
	mov ah,4Ch
	int 21h
end start

а эта программа переводит шестнадцатеричное значение в result для вывода на экран

; masm dos exe #
.286
.model small
.code
start:	mov ax,@data
	mov ds,ax
	mov es,ax
	mov ax,3
	int 10h; чистим экран
	mov si,offset result
        mov di,si
	mov bx,len/2;длина результата в словах
@@:	lodsb
	xchg al,byte ptr result[bx+1]
	stosb
	dec bx
	jnz @b
; перевожу hex->dec
	mov si,offset terminator-1;
@3:	mov cx,len;длина в байтах значения делимого
	mov di,offset result
	xor ax,ax
@@:	mov al,[di];делимое
	div ten
	stosb
	loop @b
	or [si],ah;остаток
	dec si
	cmp word ptr [di-2],0
	jne @3
	cmp word ptr [di-4],0
	jne @3
; вывожу на экран
	inc si
	mov dx,si
	mov ah,9
	int 21h
	mov ah,0
	int 16h
	mov ah,4Ch
	int 21h;выходим из программы
.data
result	dd 0FFFFFFFFh
len = $-result
ten db 10
buffer db 14 dup ('0')
terminator db '$'
end start

[Teor]

Всем спасибо за ответы. Вы помогли мне даже больше, чем нужно было