Создание окна(asm) с использованием WinApi

[Alex1991]

Как можно создать главное окно программы на примере этого кода:

.386 
.model flat, stdcall 
ExitProcess PROTO      ,:DWORD 
MessageBoxA PROTO      ,:DWORD, :DWORD, :DWORD, :DWORD 
.data 
   MsgBoxCaption  db "Пример окна сообщения",0 
   MsgBoxText     db "Программировать на Ассемблере под Win32 очень просто!",0 
.const 
   NULL        equ  0 
   MB_OK    equ  0 
.code 
   Main: 
    INVOKE    MessageBoxA, NULL, ADDR MsgBoxText, ADDR MsgBoxCaption, MB_OK 
    INVOKE    ExitProcess, NULL 
   end Main

Какую функцию winapi нужно использовать ?
Может эту? :

int WINAPI WinMain (HINSTANCE hInst, HINSTANCE hPrev,  LPSTR lpCmd, int nShow)
{
//code
}

[Пепел Феникса]

WinMain это точка входа.

а показаный вами асм код, сам по себе не создает окна, а вызывает стандартный диалог MessageBox(эта функция его и показывает и создает)

если надо свое собственное окно, то RegisterClass(Ex)+CreateWindow +цикл сообщений

[Ibanez Wizard]

Для отображения окна, надо скачала зарегистрировать класс окна (заполнить структуру WNDCLASSEX и зарегистрировать RegisterClassEx) в точке входа, потом создать окно CrerateWindowEx, потом отобразить его, а дальше запустить бесконечный цикл, в котором будут приниматься и отправляться сообщения от окна оконной процедуре (WindowProc).
Более подробно об этом написано в цикле статей Icezelion'а на wasm.ru (в данный момент он почему то не работает).

[Пепел Феникса]

вообще не обязательно именно Ex версии брать

[Ibanez Wizard]

Сообщение от Пепел Феникса

вообще не обязательно именно Ex версии брать

Это я по привычке

[Mikl___]

Alex1991
Это на МАСМе написано для WinXP

.686P 
.model flat
includelib user32.lib
includelib kernel32.lib
include windows.inc
extern _imp__CreateWindowExA@48:dword
extern _imp__DefWindowProcA@16:dword
extern _imp__DispatchMessageA@4:dword
extern _imp__GetMessageA@16:dword
extern _imp__ExitProcess@4:dword
extern _imp__RegisterClassA@4:dword
.code
start:	xor ebx,ebx
	mov edi,offset wTitle
        mov esi,400000h
	push edi
	push ebx
	push COLOR_WINDOW+1
	push 10011h
	push ebx
	push esi
	push ebx
	push ebx
	push offset WndProc
	push ebx
	push esp
	call _imp__RegisterClassA@4
	push ebx	   
	push esi
        shl esi,9;esi=CW_USEDEFAULT
	push ebx	
	push ebx	
	push esi	
	push esi	
	push esi	
	push esi	
	push WS_OVERLAPPEDWINDOW + WS_VISIBLE
	push edi; szWinTitle			
	push edi; lpszClassName
	push ebx
	call _imp__CreateWindowExA@48	;создать окно
	mov ebp,esp
message_loop: push ebx  ;цикл обработки сообщений
	push ebx
	push ebx
	push ebp 
	call _imp__GetMessageA@16	
	push ebp
	call _imp__DispatchMessageA@4     ;вернуть управление Windows        
	jmp short message_loop
WndProc:
        cmp dword ptr [esp+8],WM_DESTROY;Msg,WM_DESTROY
	je short @@WM_DESTROY
        jmp _imp__DefWindowProcA@16   ;все сообщения, не обрабатываемые в функции WndProc, направляются на обработку по умолчанию	
@@WM_DESTROY: push ebx    ;завершение программы
	call _imp__ExitProcess@4	
.data
	wTitle 	db 	'Iczelion Tutorial #3:A Simple Window in masm',0
end start

Ibanez Wizard
Всё на WASM.RU/FORUM работает