Использование регулярных выражений для извлечения части строки

[Meta2]

Всем доброго дня! прошу помочь в решении задачи по извлечению данных из строки при помощи регулярных выражений.

Дано: Есть большое количество строк, содержащих описания серверов. В каждой такой строке встречается подстрока вида /XxYGbAB/, где:
X - количество модулей памяти, установленных в сервер;
Y - ёмкость одного модуля памяти;
AB - тип памяти. Может принимать значения "RD", "UD" или "R2D"
Данное заклинание отделено от остальных данных косыми чертами.

Например (часть строки опущена):
ProLiant DL320G6 E5520 (1URack X2,26GHzQuadCore/8Mb/2x2GbUD/P...
ProLiant DL320G6 L5609 (1URack X1,86GHzQuadCore/12Mb/2x2GbUD/...
ProLiant DL320G6 E5630 RPS (1URack X2,53GHzQCore/12Mb/3x2GbRD/...
ProLiant DL320G6 E5503 (1URack X2,0GHzDualCore/4Mb/2x2GbRD/4po...
ProLiant DL320G6 E5603 (1URack X1,66GHzQuadCore/4Mb/2x2GbRD/S...
Proliant ML330T06 E5606 LFF (Tower XeonQC 2.13GHz(8Mb)/2x2GbUD/...
Proliant DL360R07 E5620 (Rack1U XeonQC 2.4Ghz(12Mb)/3x4GbR2D/P4...

Прошу помочь в написании функции, которая принимала на вход строку, а возвращала бы три значения: количество модулей, их объём и тип.

Пробовал писать с помощью классического InStr, получается очень долго и как-то коряво.

Я даже написал регулярное выражение, которое ищет подстроку: "\d[x]\dGb[RU]2?[D]"

[EugeneS]

добрый день, Meta2, см. вложение, код "test"

[vikttur]

Я без особых выражений (настроение хорошее ) написал формулы. Вдруг кому пригодятся.

[Meta2]

А я уже сам разобрался с регулярным выражением и написал готовый скрипт

Sub ParseServerNames()

Dim row_count As Integer: row_count = 2

Dim sh As Worksheet: Set sh = ActiveSheet

Dim sStr1 As String

Do While (sh.Cells(row_count, 1).Value <> "")
    
    sStr1 = sh.Cells(row_count, 2).Value
    
    Dim objRegEx As Object
    Set objRegEx = CreateObject("VBScript.RegExp")
    With objRegEx
        .Global = True
        .IgnoreCase = True
        .Pattern = "(\d)+[x]\dGb[RU](\d)?[D]"
        Set Matches = .Execute(sStr1)
    
        If Matches.Count <> 0 Then
    
            .Pattern = "(\d)+[x]"
            Set Qty = .Execute(Matches.Item(0).Value)
            sh.Cells(row_count, 6).Value = Left(Qty.Item(0).Value, Qty.Item(0).Length - 1)
            
            .Pattern = "[x]\d"
            Set Cap = .Execute(Matches.Item(0).Value)
            sh.Cells(row_count, 5).Value = Right(Cap.Item(0).Value, 1)
            
            .Pattern = "Gb[RU]"
            Set mType = .Execute(Matches.Item(0).Value)
            sh.Cells(row_count, 4).Value = Right(mType.Item(0).Value, 1)
        End If
    End With
    
    Set objRegEx = Nothing
    
    row_count = row_count + 1
Loop

End Sub

[Казанский]

Хорошо, но подстроки можно выделить за один раз - это то, что Вы берете в круглые скобки:

Sub ParseServerNames()
Dim c As Range
With CreateObject("VBScript.RegExp")
    .IgnoreCase = True
    .Pattern = "/(\d+)x(\d+)Gb([RU]2?)\D/"
    For Each c In ActiveSheet.UsedRange.Columns(2).Cells
        With .Execute(c)
            If .Count Then
                c(, 5) = .Item(0).submatches(0)
                c(, 4) = .Item(0).submatches(1)
                c(, 3) = .Item(0).submatches(2)
            End If
        End With
    Next
End With
End Sub