FASM передвинуть курсор мыши

[AlphaGh0St]

Всем привет!
Препод дал не большое задание: написать программку на fasm, которая передвигает курсор мыши на нажатию на одну из клавиш-стрелок.
Например, нажали клавишу "вверх", курсор мыши передвинулся вверх.

По идее, всё просто:
- в бесконечном цикле ожидаем нажатие клавиши.
- определяем, какая из клавиш-стрелок была нажата.
- суммируем/вычитаем текущие координаты курсора в соответствии с нажатой клавишей и переводим курсор на новую позицию.

Просто в теории, в реализации чуть сложнее.
- Подскажите, как определить, какая клавиша была нажата?
- Если не ошибаюсь, для установки координат курсора используется функция setCursorPos, можно пример её использования?

[rpy3uH]

Сообщение от AlphaGh0St

- Подскажите, как определить, какая клавиша была нажата?

банально, но факт, через хуки

[asmars]

Перехват нажатия клавиши.
На сколько я понимаю можно через int 16h, это сервис БИОС для работы с клавиатурой.

[AlphaGh0St]

Я не силён в низкоуровневом программировании и ассемблере, потому и создал тему.
Не могли бы вы подробнее рассказать о перехватах нажатых клавиш?

[asmars]

mov ah,10h            ;запрашивает ввод с клавиатуры
int 16h

после этого в ah находиться скан код клавиши нажатой.
в al ascii код .

[Ang15]

Asmar, в задании говорится, что нужно двигать курсор мыши, используя системный вызов SetCursorPos. Сл-но, программными bios-прерываниями здесь не обойтись. Т.к. это простая лаба, требуется, скорее всего, создать простое Window-приложение.

Программа, по заказу:
1. показывает, как обрабатывать сообщения
2. показывает, как работает в ассемблере SetCursorPos

.386p
.model flat,stdcall
includelib c:\assembler\masm6.15\lib\user32.lib
includelib c:\assembler\masm6.15\lib\kernel32.lib
...
WM_CHAR equ 102h
...
extern SetCursorPos@8:near
extern GetMessage@16:near
extern TranslateMessage@4:near
extern DispatchMessage@4:near
...
msgstruct struc
  mshwnd dd ?
  msmessage dd ?
  mswparam dd ?
  mslparam dd ?
  mstime dd ?
  mspt dd ? ; Положение курсора во время посылки сообщения
msgstruct ends
...
data segment dword public use32 'data'
  msg msgstruct <?>
  ...
data ends
code segment dword public use32 'code'
start:
  ...
  ;тот самый бесконечный цикл
msg_loop:
  push 0
  push 0
  push 0
  push offset msg
  call GetMessageA@16
  cmp eax,0
  je end_loop
  push offset msg
  call TranstaleMessage@4
  push offset msg
  call DispatchMessageA@4
  jmp msg_loop
end_loop
  ...
  ;выход из программы
  ...
  ;процедура окна, сюда попадают все сообщения, перехваченные GetMessage
wndproc proc
  push ebp
  mov esp,ebp
  push ebx
  push esi
  push edi
  cmp dword ptr [ebp+0CH],WM_CHAR
  je wmchar
  ...
wmchar:
  cmp dword ptr [ebp+10h],'w'
  je movcursor
  cmp dword ptr [ebp+10h],'W'
  je movcursor
movcursor:
  push 300h
  push 400h
  call SetCursorPos@8
  ...
code ends
end start

В программе, правда, не используется хук (SetWindowHookEx), но сообщение всё-равно обрабатывается.

Правда, код для masm, т.к. fasm не знаю.

Шаблон создания простого 32-разрядного Windows-приложение см. Пирогов. Assembler для Windows.

Программа реагирует на нажатие клавиши W. Можно попробовать через скан-код. Хранится также в сообщение в lParam.

Для 32-разрядных приложений лучше скачать Win32.hlp (описание системных вызовов на английском). Сайт тут небольшой нашёл, глянь туда http://www.vsokovikov.narod.ru/ (то же, только на русском).

[AlphaGh0St]

Проблема с получением текущих координат курсора мыши - решена.
Привожу код:

include 'include/win32ax.inc'

.data
    strMess db 'x: %d; y: %d', 0
    buff db 30 DUP(?)
    pt POINT

.code
    main:
	invoke GetCursorPos, addr pt

        invoke wsprintf, addr buff, addr strMess, [pt.x], [pt.y]
        invoke MessageBox, 0, buff, "mouse", MB_OK

	add [pt.x], 100
        add [pt.y], 100

	invoke SetCursorPos, [pt.x], [pt.y]    

        invoke ExitProcess, 0
    .end main

[AlphaGh0St]

Ну вот и всё, задача решена.
Ниже привожу исходный код.
Всем спасибо за помощь!

format PE GUI 4.0

include 'include\win32ax.inc'

.data
    _class TCHAR 'FASMWIN32', 0
    _title TCHAR 'Перемещение курсора', 0
    _error TCHAR 'Ошибка создания формы', 0

    wc WNDCLASS 0, WindowProc, 0, 0, 0, 0, 0, COLOR_BTNFACE+1, 0, _class
    msg MSG

    pt POINT

.code
    main:
        invoke GetModuleHandle, 0
        mov [wc.hInstance], eax

        invoke LoadIcon, 0, IDI_APPLICATION
        mov [wc.hIcon], eax

        invoke LoadCursor, 0, IDC_ARROW
        mov [wc.hCursor], eax

        invoke RegisterClass, wc
        test eax, eax
        jz error

        invoke CreateWindowEx, 0, _class, _title, WS_VISIBLE+WS_DLGFRAME+WS_SYSMENU, 128, 128, 360, 200, 0, 0, [wc.hInstance], 0
        test eax, eax
        jz error

        msg_loop:
            invoke GetMessage, msg, 0, 0, 0
            cmp eax, 1
            jb end_loop
            jne msg_loop

            invoke TranslateMessage, msg
            invoke DispatchMessage, msg
            jmp msg_loop

        error:
            invoke MessageBox, 0, _error, 0, MB_ICONERROR+MB_OK

        end_loop:
            invoke ExitProcess, [msg.wParam]

            proc WindowProc hwnd:DWORD, wmsg:DWORD, wparam:DWORD, lparam:DWORD
            cmp [wparam], VK_UP
            je keyUpPressed

            cmp [wparam], VK_DOWN
            je keyDownPressed

            cmp [wparam], VK_LEFT
            je keyLeftPressed

            cmp [wparam], VK_RIGHT
            je keyRightPressed

            cmp [wmsg], WM_DESTROY
            je wmdestroy

        defwndproc:
            invoke DefWindowProc, [hwnd], [wmsg], [wparam], [lparam]
            jmp finish

        keyUpPressed:
            invoke GetCursorPos, addr pt
            sub [pt.y], 10
            invoke SetCursorPos, [pt.x], [pt.y]
            ret

        keyDownPressed:
            invoke GetCursorPos, addr pt
            add [pt.y], 10
            invoke SetCursorPos, [pt.x], [pt.y]
            ret

        keyLeftPressed:
            invoke GetCursorPos, addr pt
            sub [pt.x], 10
            invoke SetCursorPos, [pt.x], [pt.y]
            ret

        keyRightPressed:
            invoke GetCursorPos, addr pt
            add [pt.x], 10
            invoke SetCursorPos, [pt.x], [pt.y]
            ret

        wmdestroy:
            invoke PostQuitMessage, 0
            xor eax, eax

        finish:
            ret

    endp
    .end main

[Ang15]

GetCursorPos. Не подумал о нём.