замена текста в ячейке

[Y@R]

Всем привет. Я тут первый раз, поэтому сильно не ругайте.
Задача вот в чем, Есть большой файл excel, где в столбце А периодически встречаются ячейки с одним и тем же текстом. Пусть к примеру текст будет AAABBB. Нужно текст в таких ячейках заменить на текст ячейки, которая выше данной. С VBA не сталкивался сроду. Простую замену вроде освоил, а как тут поступить- не могу сообразить.
спасибо заранее

[Скрипт]

Y@R, есть два способа решения вашей задачи с учётом форматирования (форматирование - это, например, размер шрифта, цвет шрифта):

1. один способ сохраняет форматирование, но при больших объёмах данных будет медленно работать;
2. второй способ не сохраняет форматирование, но при больших объёмах данных сработает быстрее.

Какой вариант вам подходит?

[Y@R]

форматирование - Вы что имеете ввиду? Регистр текста? он неважен. Главное чтобы было понятно написано

[Скрипт]

Y@R, форматирование - это внешний вид данных, например, цвет шрифта, размер шрифта, что-то ещё.

В программе "Excel" нет такого элемента форматирования "регистр". В программе "Word" есть.

Поэтому если использовать второй вариант из сообщения #2, то регистр останется.

Какой вариант вам подходит?

[Y@R]

а - форматирование неважно. главное, чтобы текст остался

[Скрипт]

Y@R, я форумулы не учёл ещё. Формулы есть в столбце "A"? При втором способе формулы пропадут.

[Y@R]

не не - в столбце а только текст - наименование товаров из прайса.
и ещё вдогонку. Хотелось бы ещё удалить все строки, у которых в столбце h пусто.
Это было бы идеально

[Скрипт]

По первому вопросу

Код работает с активным листом, со столбцом "A" в диапазоне "A1:A100".

Sub Procedure_1()
    
    '1. Создаём в оперативной памяти компьютера поименованную
        'область - константу "mySearchText".
    'В эту константу поместим данные, которые нужно искать.
    Const mySearchText As String = "AAABBB"

    '2. Создаём в оперативной памяти компьютера поименованную область - массив.
    'В него поместим данные из Excel-книги, чтобы макрос быстрее работал.
    'Т.к. работа с самими ячейками медленнее.
    Dim myArray() As Variant
    
    '3. Создаю в оперативной памяти компьютера различные поименованные области -
        'переменные, которые понадобятся для написания кода.
    Dim i As Long
    
    '4. Помещаю данные из Excel-листа в массив "myArray".
    myArray() = Range("A1:A100").Value
    
    'Двигаемся по массиву сверху вниз.
    'Цикл "For ... To ... Step " - используется, чтобы делать одну
        'и ту же команду несколько раз.
    'UBound(myArray, 1) - это количество строк в массиве.
    'Двигаюсь со второй строки, т.к. у первой строки сверху нечего брать.
    For i = 2 To UBound(myArray, 1) Step 1
        'С помощью "If ... Then ... End If" выбираем, какое действие сделать.
        '5. Если в элементе массива есть искомый текст, то
            'берём данные из элемента выше.
        If myArray(i, 1) = mySearchText Then
            myArray(i, 1) = myArray(i - 1, 1)
        End If
    Next i
    
    '6. Вставляем данные обратно на Excel-лист.
        'С помощью "Resize" указываем, куда вставить данные
        'относительно ячейки "A1". В вашем случаем можно было бы просто записать:
        'Range("A1:A100").Value =myArray()
        'Это я на всякий случай написал.
    Range("A1").Resize(UBound(myArray, 1), 1).Value = myArray()
    
End Sub

[Скрипт]

По второму вопросу

Можно использовать "фильтр" - отобрать то, что нужно, а потом удалить. Можно сделать вручную. Если вручную долго делать, то можно макрос написать.

Можно попробовать вот такой макрос:

Sub Procedure_2()

    Dim myRangeForDelete As Excel.Range
    
    '1. Получаем доступ в столбце "H", к диапазону ячеек "H1:H100",
        'к ячейкам, которые пустые.
    Set myRangeForDelete = Range("H1:H100").SpecialCells(xlCellTypeBlanks)
    
    '2. Удаляем целые строки.
    '"EntireRow" используется, чтобы получить доступ к строкам.
    myRangeForDelete.EntireRow.Delete
    
End Sub

Только первое время проверяйте - все ли пустые ячейки удаляются. Потому что VBA-Excel-команда "SpecialCells" работает по правилам, которые в VBA-справке не описаны. Например, может дать неправильный результат, если внесли изменения, а книгу не сохранили.

[Y@R]

огромное спасибо - всё заработало) - круто. По итогу 30000 строк обработал менее чем за минуту - супер.
оч благодарен