VBA в Access

[Ангел без крыльев]

Многоуважаемые программисты!! Нужна помощь с VBA в Access =(
В базе данных есть форма "Добавление пары", на ней внизу есть кнопка, с помощью которой в таблицу Расписание добавляется пара с введенными данными.
И мне надо на ней прописать код, чтобы, при совпадении вводимых данных с уже существующей строкой, оно не добавлялось,а выдавало ошибку
я пробовала...там есть код..но он не хочет работать..я просто впервые столкнулась с VBA и не могу разобраться...
помогите, пожалуйста)

Private Sub Кнопка31_Click() 'Кнопка добавить занятие
    
Dim bd As Database, tab1 As Recordset
Dim str As String

Set bd = DBEngine.Workspaces(0).Databases(0)
Set bd = CurrentDb
   
   
If ((Me.Аудитория.Value <> "") And (Me.Время.Value <> "") And (Me.Группа.Value <> "") And (Me.День_недели.Value <> "") And (Me.Неделя.Value <> "") And (Me.Предмет.Value <> "") And (Me.Преподаватель.Value <> "")) Then
   Set tab1 = bd.OpenRecordset("Расписание")
      
      If ((Me.Время.Value <> tab1!Время) And (Me.Преподаватель.Value <> tab1!Преподаватель)) Then
         DoCmd.GoToRecord , , acNewRec
         Else: MsgBox "Поле с таким название есть!"
       End If
       
     Else: MsgBox "Заполните все поля"
End If
   
Me.День_недели.Value = ""
Me.Неделя.Value = ""
Me.Время.Value = ""
Me.Группа.Value = ""
Me.Аудитория.Value = ""
Me.Тип_занятия.Value = ""
Me.Предмет.Value = ""
Me.Преподаватель.Value = ""

End Sub

[Woodlin]

Ангел без крыльев, попробуйте очистить источник записей формы "Добавление пары" и его контролов, а запись добавлять в таблицу через рекордсет

Private Sub Кнопка31_Click() 'Кнопка добавить занятие
 . . . ' здесь Ваш код
    
   Set tab1 = bd.OpenRecordset("Расписание", dbOpenDynaset)
    
    tab1.MoveLast 'Заполняем рекордсет
    
    'Ищем запись в рекордсет запись, удовлетворяющую условию:
    tab1.FindFirst "Время = '" & Me.Время.Value & "' and Преподаватель = " & Me.Преподаватель.Value
    
    If tab1.NoMatch Then ': запись не найдена, значит можно добавлять новую
        tab1.AddNew
            tab1![День недели].Value = Me!День_недели.Value
            tab1!Неделя.Value = Me!Неделя.Value
            tab1!Время.Value = Me!Время.Value
            tab1!Группа.Value = Me!Группа.Value
            tab1!Аудитория.Value = Me!Аудитория.Value
            tab1![Тип занятия].Value = Me![Тип занятия].Value
            tab1!Предмет.Value = Me!Предмет.Value
            tab1!Преподаватель.Value = Me!Преподаватель.Value
        tab1.Update
        'Запись внесена, очищаем поля формы
        Me.День_недели.Value = ""
        Me.Неделя.Value = ""
        Me.Время.Value = ""
        Me.Группа.Value = ""
        Me.Аудитория.Value = ""
        Me.Тип_занятия.Value = ""
        Me.Предмет.Value = ""
        Me.Преподаватель.Value = ""
        
    Else: MsgBox "Поле с таким название есть!"
    End If
       
Else: MsgBox "Заполните все поля"
End If

End Sub

[Ангел без крыльев]

все работает) Спасибо огромное!!!)
скажите, а если мне надо несколько условий..первое условие - на совпадение времени и преподавателя, второе, например, на совпадение аудитории, группы и времени, третье еще на что-нибудь...как их прописать тогда? и возможно ли сделать разный MsgBox?
заранее огромное спасибо

и у меня не получается прописать в сточку с условием больше двух... объясните, плиз, синтаксис условия FindFirst

[Woodlin]

Сообщение от Ангел без крыльев

скажите, а если мне надо несколько условий..первое условие - на совпадение времени и преподавателя, второе, например, на совпадение аудитории, группы и времени, третье еще на что-нибудь...как их прописать тогда?...как их прописать тогда? и возможно ли сделать разный MsgBox?

Все три условия Вы будете по отдельности проверять, или они должны сработать одновременно?
В первом случае я бы ввёл какую-нибудь переменную, к примеру strMsgBox типа String, и проверял каждое условие по отдельности. Если время и преподаватель например уже такие есть, то

strMsgBox = "Выберите другое время и преподавателя" & VbCrlf

В следующем условии

strMsgBox = strMsgBox  & "Свое условие" & VbCrlf

И так далее.
Если после проверки всех условии переменная пустая то совпадений нет, иначе выпадет сообщение со всеми совпавшими условиями.

If strMsgBox = "" Then
   'Совпадений нет, можно добавлять в таблицу
Else
   'Совпадения есть
   Msgbox (strMsgBox)
End If

Если Вам нужно проверить все три условия за раз, то можно собрать строку в критерии отбора FindFirst, или создать запрос (можно в конструкторе) и использовать его как источник строк при открытии рекордсет

Set tab1 = bd.OpenRecordset("Имя_Запроса", dbOpenDynaset)

Если запись(и) в рекордсет есть, значит совпадения есть.

Сообщение от Ангел без крыльев

и у меня не получается прописать в сточку с условием больше двух... объясните, плиз, синтаксис условия FindFirst

В общем, то синтаксис приведён в примере и есть в справке.
При собирании строки нужно знать тип данных. Если строковый, то использовать одинарные кавычки

tab1.FindFirst "Время = '" & Me.Время.Value & "'"

если целое число

tab1.FindFirst "Преподаватель = " & Me.Преподаватель.Value