Проверка данных на совпадение

[A_next]

Ребят помогите необразованному
Надо в екселе проверить по столбцу номер телефона из списка на другой странице и при совпадении номера перенести СТРОКУ на отдельную страницу Заранее все благодарен за помощь!

[VictorM]

Как-то нашел в инете, уже и не помню где, вот такой макрос

Private Sub MacrosSearch_Text()
    If ThisWorkbook.ProtectStructure = True Then
       MsgBox "Структура рабочей книги защищена", vbCritical, "Создание отчёта-нового листа невозможно"
       Exit Sub
    End If
    
    iText$ = "Яблоко" 'образец для поиска
    
    Dim iCell As Range
    Set iCell = Me.UsedRange.Find(What:=iText$, LookIn:=xlValues, LookAt:=xlPart)
    'Если необходимо использовать строгое соответствие, то замените константу xlPart на xlWhole
    
    If Not iCell Is Nothing Then
       Application.ScreenUpdating = False
       With Worksheets.Add(After:=Sheets(Sheets.Count))
            iAddress$ = iCell.Address
            Do
                 iRow& = iRow& + 1
                 iCell.EntireRow.Copy Destination:=.Rows(iRow&)
                 Set iCell = Me.UsedRange.FindNext(After:=iCell)
            Loop While Not iCell Is Nothing And iCell.Address <> iAddress$
       End With
       Application.ScreenUpdating = True
    End If
End Sub

К сожалению не знаю автора.
Работает отлично, уже много раз применял в разных вариантах.

[A_next]

Сообщение от A_next

Ребят помогите необразованному
Надо в екселе проверить по столбцу номер телефона из списка на другой странице и при совпадении номера перенести СТРОКУ на отдельную страницу Заранее все благодарен за помощь!

Что никто не сталкивался с подобным? или что то очень сложное я написал? В ехселе это реально сделать то хоть? Искал программы подобные , ничего не смог найти. Заранее благодарен всем за участие.

[Serge_Bliznykov]

Что никто не сталкивался с подобным?

т.е. Вы пост #2 на этой странице от VictorM не заметили?

[SAS888]

Пусть исходные данные находятся в столбце "A" на листе "Data". Пусть список находится в столбце "A" на листе "List". Пусть требуется вывести совпадающие данные в столбец "A" на лист "Result" (который может и отсутствовать).
Можно так:

Sub Main()
    Dim i As Long, j As Long, a(), b(), c(), x
    Set x = CreateObject("Scripting.Dictionary")
    Application.ScreenUpdating = False: Application.DisplayAlerts = False
    With Sheets("Data"): a = .Range("A1:A" & .Cells(Rows.Count, 1).End(xlUp).Row).Value: End With
    With Sheets("List"): b = .Range("A1:A" & .Cells(Rows.Count, 1).End(xlUp).Row).Value: End With
    For i = 1 To UBound(b, 1)
        If Not x.Exists(b(i, 1)) Then x.Add b(i, 1), i
    Next
    ReDim c(1 To UBound(a, 1), 1 To 1): j = 0
    For i = 1 To UBound(a, 1)
        If x.Exists(a(i, 1)) Then
            j = j + 1: c(j, 1) = a(i, 1)
        End If
    Next
    On Error Resume Next: Sheets("Result").Delete: On Error GoTo 0
    Sheets.Add.Name = "Result"
    If j > 0 Then [A1].Resize(UBound(c, 1)).Value = c
End Sub