заполнение даних из закрытого файла

[Pasha_Z]

Подскажите как перенести значения (данные) с ячеек E8:X60 закрытого файла под именем ДАТА_01, который находится тот же папку что и открытый файл ДАТА_00 в ячейки E8:X60.

[IgorGO]

открыть, скопировать и закрыть.

если сделать все быстро - может ни кто и не заметит.

можно запросом, если там обычная таблица с шапкой и строками данных.

[Pasha_Z]

Сообщение от IgorGO

можно запросом, если там обычная таблица с шапкой и строками данных.

Там таблицы одинаковые.
желательно не открывать файл.
просто переносится фактически от разных файлов на разные листы открытого файла.

[IgorGO]

а Вы полагаете запрос может взять данные из файла не открывая его?
запросу тоже надо получить доступ к данным.
нет доступа - нет данных.

[Hugo121]

Тем более что нужно перенести. А это подразумевает изменение исходного файла.
Или не нужно переносить?

[alex77755]

Где-то попадался примерчик:

В VBA не существует метода получения значения из закрытого файла рабочей
книги. Однако вы можете воспользоваться возможностью управления ссылками на
файлы, которая предоставляется в Excel. В настоящем разделе описана функция VBA
(GetValue, показанная ниже), которая получает значение из закрытой книги.
Эта задача выполняется в результате вызова макроса XLM.
Код 1

Private Function GetValue(path, file, sheet, ref)
Dim arg As String
If Right(path, 1) <> "\" Then path = path & "\"
If Dir(path & file) = "" Then
GetValue = "Файл не найден"
Exit Function
End If
arg = "'" & path & "[" & file & "]" & sheet & "'!" & _
Range(ref).Range("A1").Address(, , xlR1C1)
GetValue = ExecuteExcel4Macro(arg)
End Function

Функция GetValue имеет четыре аргумента:
¦ path – путь к закрытому файлу (например, "d:\files");
¦ file – название рабочей книги (например, "budget.xls");
¦ sheet – название рабочего листа (например, "Лист1");
¦ ref – ссылка на ячейку (например, "C4").
Следующая процедура демонстрирует, как используется функция GetValue.
В этой процедуре отображается значение ячейки А1 листа Лист1 файла 99Budget.xls
(папка XLFiles\Budget на диске c:.
Код 1

Sub TestGetValue()
p = "c:\XLFiles\Budget"
f = "99Budget.xls"
s = "Лист1"
a = "A1"
MsgBox GetValue(p, f, s, a)
End Sub

Ниже приведен еще один пример. Эта процедура считывает 1200 значений
(100 строк и 12 столбцов) из закрытого файла и помещает эти значения на активный
рабочий лист.
Код 1

Sub TestGetValue2()
p = "c:\XLFiles\Budget"
f = "99Budget.xls"
s = "Sheet1"
Application.ScreenUpdating = False
For r = 1 To 100
For c = 1 To 12
a = Cells(r, c).Address
Cells(r, c) = GetValue(p, f, s, a)
Next c
Next r
Application.ScreenUpdating = True
End Sub

[IgorGO]

Что тут скаазть...

прочитать данные из файла не открывая файл - это мастерство!!!

полагаю следующим этапом будет написание макроса, с помощью которого можно выпить пиво из бутылки не открывая ее.

[kuklp]

Ага. Наивные... Предлагаю желающим "не открывая", тренировать силу мысли. Так быстрей получится.

[SAS888]

И, все-таки: то, что файл-источник так, или иначе все равно открывается, при любом способе получения данных - это очевидно. Но, если открывать "тяжелый" файл, содержащий большое количество листов, формул, ссылок, объектов, форматов и т.п. методом Open, то это будет долго. В таком случае, действительно, лучше либо воспользоваться, как предлагает alex77755 и Дж. Уокенбах макросом XLM (пример из поста №6), либо вставить ссылки в ячейки, получить по ним значения и удалить ссылки, оставив значения. Например, так:

Sub qq()
    Application.ScreenUpdating = False
    With Range("E8:X60")
        .Formula = "='" & ThisWorkbook.Path & "\[ДАТА_01.xls]Лист1'!" & .Address
        .Value = .Value
    End With
End Sub

Необходимо отметить, что в том и другом случае, кроме пути, имени файла и диапазона ячеек, так же требуется заранее знать имя листа из файла-источника.
А если открывать, копировать и закрывать, то лучше так:

Sub qq()
    Dim f As String: Application.ScreenUpdating = False
    f = ThisWorkbook.Path & "\" & "ДАТА_01.xls"
    [E8:X60].Value = GetObject(f).Worksheets("Лист1").[E8:X60].Value
    GetObject(f).Close False
End Sub

[Pasha_Z]

Спасибо всем за интересные ответы.
буду определяться с вариантами решения своей задачи.