Удалить лишние пробелы

[Max00766]

Нужно было написать программу уплотнения текста, то-есть заменит несколько пробелов на 1, код я нашел на другом форуме, но после выполнения программы дос бокс зависает, подскажите почему? И как сделать что бы уплотненная строка выводилась не в одну строчку со старой, а с новой строки.
И очень буду благодарен за комментарии к коду, так как для себя хочу в ассемблере разобраться, но пока что почти полный профан и не могу разобраться в коде, заранее большое спасибо

ASSUMe CS:CODE,DS:CODE,ES:CODE
CODE segment
org 100h
start:
mov di,offset startstring
mov cx,0
foreverloop:
mov ah,10h
int 16h
mov dl,al
mov ah,2
int 21h
mov [di],dl
inc di
cmp dl,'.'
je outlrfwrwr
inc cx
jmp foreverloop
outlrfwrwr:
 
mov si,offset startstring
mov di,offset endstring
loopwerwtwty:
mov ax,[si]
cmp ax,2020h
je nosigse
mov [di],al
inc di
nosigse:inc si
loop loopwerwtwty
 
inc di
push ax
mov al,10
mov [di],al
mov al,13
mov [di],al
mov al,'$'
mov [di],al
pop ax
mov ah,9
mov dx,offset endstring
int 21h
mov ah,10h
int 16h
int 20h
startstring db 30000 dup (?)
endstring db 30000 dup (?)
CODE ends
end start

Безымянный.jpg

[R71MT]

Сообщение от Max00766

после выполнения программы дос бокс зависает, подскажите почему?

Большие буфера (красивы только у женщин).
Уменьши их до 80..

startstring db 80 dup (?)
endstring db 80 dup (?)

[Max00766]

Сообщение от R71MT

Большие буфера (красивы только у женщин).
Уменьши их до 80..

startstring db 80 dup (?)
endstring db 80 dup (?)

Все равно виснет, уже даже 50 уменьшил, но без результата.

[R71MT]

;== FASM code =======================
org 100h
jmp start

mess0    db   13,10,' String:  $'
mess1    db   13,10,' Result:  $'
buff:                            ; структура буфера для fn(0Ah)
max      db   80                 ; макс. размер
size     db   0                  ; кол-во введённых символов
string   db   80 dup(0)          ; сам буфер для строки

start:
       mov   dx,mess0            ;
       call  message             ;
       mov   ah,0Ah              ; ввод строки в буфер
       mov   dx,buff             ;
       int   21h                 ;

       xor   cx,cx               ;
       mov   cl,[size]           ; длина строки
       mov   si,string           ; SI/DI - адрес строки
       mov   di,si               ;
       xor   ax,ax               ;
cycle: lodsb                     ; считать символ в AL
       cmp   al,' '              ; пробел?
       jne   miss                ; нет - пропускаем
       cmp   ax,'  '             ; да - тест с предыдущим
       je    next                ; 2 пробела - пропускаем
miss:  stosb                     ; перезапись символа
next:  xchg  ah,al               ; запомним текущий символ
       loop  cycle               ; мотаем СХ-раз..
       mov   al,'$'              ;
       stosb                     ; вставляем маркер конца стоки

       mov   dx,mess1            ;
       call  message             ;
       mov   dx,string           ; выводим изменённую строку
       call  message             ;

exit:  xor   ax,ax               ; выход..
       int   16h                 ;
       int   20h                 ;

;ннннннннннннннннн П Р О Ц Е Д У Р Ы нннннннннннннннннннннннннннннннннннн
;------------------------------------------------------------------------
message:                      ;
      mov   ah,9              ; вывод строки на экран
      int   21h               ;
ret                           ;

[Max00766]

Сообщение от R71MT

;== FASM code =======================
org 100h
jmp start

mess0    db   13,10,' String:  $'
mess1    db   13,10,' Result:  $'
buff:                            ; структура буфера для fn(0Ah)
max      db   80                 ; макс. размер
size     db   0                  ; кол-во введённых символов
string   db   80 dup(0)          ; сам буфер для строки

start:
       mov   dx,mess0            ;
       call  message             ;
       mov   ah,0Ah              ; ввод строки в буфер
       mov   dx,buff             ;
       int   21h                 ;

       xor   cx,cx               ;
       mov   cl,[size]           ; длина строки
       mov   si,string           ; SI/DI - адрес строки
       mov   di,si               ;
       xor   ax,ax               ;
cycle: lodsb                     ; считать символ в AL
       cmp   al,' '              ; пробел?
       jne   miss                ; нет - пропускаем
       cmp   ax,'  '             ; да - тест с предыдущим
       je    next                ; 2 пробела - пропускаем
miss:  stosb                     ; перезапись символа
next:  xchg  ah,al               ; запомним текущий символ
       loop  cycle               ; мотаем СХ-раз..
       mov   al,'$'              ;
       stosb                     ; вставляем маркер конца стоки

       mov   dx,mess1            ;
       call  message             ;
       mov   dx,string           ; выводим изменённую строку
       call  message             ;

exit:  xor   ax,ax               ; выход..
       int   16h                 ;
       int   20h                 ;

;ннннннннннннннннн П Р О Ц Е Д У Р Ы нннннннннннннннннннннннннннннннннннн
;------------------------------------------------------------------------
message:                      ;
      mov   ah,9              ; вывод строки на экран
      int   21h               ;
ret                           ;

Большое спасибо

[R71MT]

Max00766, помимо заголовков, fasm отличается от остальных
отсутствием директив "offset" и "ptr". Вот примеры:

string   db  'Hello World! $'
array    dw   0123h

; на fasm'e ------------------
   mov  ah,9
   mov  dx,string
   int  21h
   mov  ax,word[array]

; на tasm/masm'e -------------
   mov  ah,9
   mov  dx,offset string
   int  21h
   mov  ax,word ptr[array]

..а для спасибо есть весы под аватаркой

[Max00766]

Сообщение от R71MT

Max00766, помимо заголовков, fasm отличается от остальных
отсутствием директив "offset" и "ptr". Вот примеры:

string   db  'Hello World! $'
array    dw   0123h

; на fasm'e ------------------
   mov  ah,9
   mov  dx,string
   int  21h
   mov  ax,word[array]

; на tasm/masm'e -------------
   mov  ah,9
   mov  dx,offset string
   int  21h
   mov  ax,word ptr[array]

..а для спасибо есть весы под аватаркой

За весы спасибо что подсказали, а про отличия тасма фасма уже знаю, уже немного лед тронулся)