e^x в FPU

[NiCola999]

есть ли такая функция у сопроцессора? Мне надо посчитать кубический корень, (sqrt(x))^3 = exp(ln(x)/3)
еще нужен логарифм... ln

[Stilet]

Рекомендую достать MASM библиотеку FPULib там есть такие функции.

[airyashov]

ln(x)=log2(x)/log2(e)

[NiCola999]

ассемблер 80836, подключать ничего нельзя.

Если нету функций типо flog и fexp тогда вопрос меняется. Есть ли какая-нибудь формула кубического корня аргумента которую можно сделать c fpu

[Goodwin98]

Вот вам ф-ция возведения в степень. Разберетесь наверно

fpower		proc
		; st0=X, st1=Y

		ftst                   ; st0=X=0 ?
		fstsw	ax
		sahf
		jz	@@Zero         ; Да, результат = 0 (CF=NC=0, кстати!)
		mov	bl,ah          ; BL and 1=1 при X<0, 0 при X>0 (исп-ся после получения результата)
		ja	@@PositiveX    ; Если X>0, то никаких проверок нам больше не надо

		fxch                   ; Обмен st0 <-> st1 (st0=Y, st1=X)
		fld	st(0)          ; st2=st1=X, st1=st0=Y, st0=st0=Y
		frndint                ; st0=Round(st0)=Round(Y)
		fcomp                  ; Сраниваем st0 и st1; st0=st1=Y, st1=st2=X, st3=пусто
		fstsw	ax             ; В AH флаг ZF=ZR=1 при целом Y
		sahf                   ; Y целое?
		jnz	@@Error        ; Нет, отрицательные числа нельзя возводить в нецелую степень!

		fld1
		fld1
		fadd                   ; st2=st1=X, st1=st0=Y, st0=2
		fld	st(1)          ; st3=st2=X, st2=st1=Y, st1=st0=2, st0=st1=Y
		fprem                  ; st0=st0 mod st1=Y mod 2
		ftst                   ; st0=0 (Y mod 2=0, т.е. чётное) ?
		fstsw	ax             ; В AH флаг ZF=ZR=1 при чётном Y (CF=NC=0, кстати!)
		fstp	st(0)          ; Удаляем остаток от деления
		fstp	st(0)          ; Удаляем число 2 (st0), st0=st1=Y, st1=st2=X, st2=пусто
		fxch                   ; Обмен st0 <-> st1 (st0=X, st1=Y)
@@PositiveX:
		fabs                   ; st0=|st0|=|X|
		fyl2x                  ; st0 = st1*log2(st0) = Y*log2(|X|)
		fld	st(0)          ; st1=st0
		frndint                ; st0=Round(st0)
		fsub	st(1),st(0)    ; st1=st1-st0
		fld1                   ; st1=st0, st0=1
		fscale                 ; st0=st0*2^st1
		fstp	st(1)          ; Удаляем st1
		fincstp                ; st7=st0, st0=st1
		f2xm1                  ; st0=(2^st0)-1
		fmul	st(0),st(7)    ; st0=st0*st7
		fdecstp                ; st1=st0, st0=st7
		fadd                   ; st0=st0+st1, st0=пусто
		; Результат в st0 !!!

		test	bl,1           ; X<0 ? (CF=NC=0, кстати!)
		jz	@@End          ; Нет, завершаем
		sahf                   ; Y чётное
		jz	@@End          ; Да, завершаем
		fchs                   ; Если X<0, а Y нечётное, то меняем знак результата
@@End:		ret                    ; Выходим!
@@Error:
		fldz                   ; Заносим 0
		fstp	st(1)          ; Удаляем X
		stc                    ; CF=CY=1 - ошибка
@@Zero:
		fstp	st(1)          ; Удаляем Y
		ret                    ; Выходим!

fpower		endp

[NiCola999]

возведение в степень 1/3 нельзя, к сожалению =), есть какаято формула через логарифм не могу её найти

[airyashov]

Сообщение от NiCola999

Если нету функций типо flog и fexp тогда вопрос меняется. Есть ли какая-нибудь формула кубического корня аргумента которую можно сделать c fpu

помоему вы не обратили на мой пост внимания, обидно

[NiCola999]

airyashov я никак не мог пропустить ваш пост)

у меня есть сейчас такая формула
(sqrt(x))^3 = exp(ln(x)/3)
логарифм вы мне дали формулу, спасибо) для lg2(x) в фпу вроде fyl2x
осталась exp(x), может есть какаято простая формула для е(х) , очень не хочется считать каждый цикл факториал в формуле Тейлора=)

[airyashov]

могу предложить такое, как понимаю нужно вычислить
x^(1/3)
тогда
2^(log2(x)/3), а это можно разложить на
2^целая часть(log2(x)/3)*2^остаток(log2(x)/3)

[NiCola999]

не очень понял, как по этому находить корень, можно поподробнее пожалуйста