Удаление содержимого соседних ячеек после ввода данных.

[KOSTIK1]

Доброго времени суток всем!
Помогите с кодом ВБА у меня не получается.
Есть столбец "D" и в любой ячейке этого столбца после ввода значения (например даты) нужно чтобы соответственно в этой строке но только в столбце "G" и "К" удалялись значения, и наоборот, внеся значение в ячейку из столбца "G" значения в "D" и "Е" этой же строки, удалялись. Спасибо.

[EducatedFool]

Вот весь код:

Const Диапазон = "d:d,e:e,g:g"

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Cells.Count > 1 Then Exit Sub
    If Intersect(Target, Range(Диапазон)) Is Nothing Then Exit Sub
    Dim cell As Range: On Error Resume Next
    Application.EnableEvents = False
    For Each cell In Intersect(Target.EntireRow, Range(Диапазон)).Cells
        If cell.Address <> Target.Address Then cell.ClearContents
    Next cell
    Application.EnableEvents = True
End Sub

А вот - пример файла:




Прочитал задание ещё раз... заметил, что столбцы отличаются.
Тогда такой код испробуйте: http://excelvba.ru/XL_Files/Sample__...__18-38-22.zip

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Cells.Count > 1 Then Exit Sub
    On Error Resume Next: Application.EnableEvents = False
    Select Case Target.Column
        Case 4
            ' Есть столбец "D" и нужно чтобы в этой строке
            ' но только в столбце "G" и "К" удалялись значения
            Target.EntireRow.Cells(7).ClearContents
            Target.EntireRow.Cells(11).ClearContents
        Case 7
            ' внеся значение в ячейку из столбца "G"
            ' значения в "D" и "Е" этой же строки, удалялись.
            Target.EntireRow.Cells(4).ClearContents
            Target.EntireRow.Cells(5).ClearContents
    End Select
    Application.EnableEvents = True
End Sub

[KOSTIK1]

Превосходно! Спасибо за скорость.

[KOSTIK1]

Извиняюсь, но нужно чтобы на удаление влияли только столбцы "D" и "G".
То-есть изменив в "G" очистилось в "D" и "Е", а изменив в "D" очистилось только "G" и "К". А тут выбор в любой из перечисленных ячеек влияет на все остальные стирая их. Как можно подправить? Спасибо


PS-Поздно увидел ваше EducatedFool исправление!
Вопрос исчерпан. Ещё раз СПАСИБО.