Командный файл

[igordeg]

Помогите написать командный файл. Его задача: Из заданной директории переписать указанные шаблоном файлы в заданную директорию так, что бы были переписаны только "новые" (не существующие в приемной директории) файлы.

Первую часть (Из заданной директории переписать указанные шаблоном файлы в заданную директорию) реализовал, а вот со второй проблема...

cls
echo off

	set deldir = %1
        set dir =  %2
        set file = %3
	if "%1"=="" goto :3
	if "%2"=="" goto :2
	if "%3"=="" goto :4
                                                                   

cls
    
copy/N %1\*.%3 %2\*.%3 


exit 


:2       
	echo Wrong name off file
        echo Please repeat
	pause
	exit

:3     
        echo Wrong dir
        echo Please repeat
	pause
	exit

:4
echo Error
exit

[DenisGrek]

не работает твой файл..

[DenisGrek]

у кого есть работающий батник по этой теме?

[Serge_Bliznykov]

вариант 1.

@echo off

REM носитель
set tmpdisk=h:\
REM Каталог приемник
SET tmpdir=temp3\
REM шаблон копируемых файлов например *.bat
set list=*.pas


for %%c in (%list%) do (
    set "file=%%c"
    set "folder=%tmpdisk%%tmpdir%"
    call :MyCopy
)
goto :eof

:MyCopy
@echo off
if exist "%folder%%file%" (
      echo "File %file% already exist."
      goto :cont
      )
rem echo "coping file: %file% to %folder%%file%"
COPY "%file%" "%folder%%file%" > nul
IF ERRORLEVEL 1 echo "Error while copying file: %file%"
:cont
goto :eof

вариант 2.
должны быть два параметра: первый - путь к исходному каталогу, второй - к каталогу назначения

@echo off

for %%c in (%1\*.pas) do (
    if not exist %2\%%~nc%%~xc  copy  %%c  %2\%%~nc%%~xc
)