WORD из EXCEL

[maksim_serg]

Здравствуйте
Подскажите как в excel открыть документ word и записать в него текст? пробывал такой код, но выдает ошибку:

Dim Appl As Object
    Set Appl = CreateObject("Word.Application")
    Appl.Documents.Open ("файл")
       Selection.MoveDown Count:=11
       election.TypeText Text:="текст текст текст"
    Appl.Visible = True

[Maxx]

Sub writeWORD()
  s = ThisWorkbook.Path & "\doс.doc" ' по умолчанию файл Ворд в тоже папке. или поменяйте путь
  Dim wrdApp As Object: Set wrdApp = CreateObject("Word.Application")
  With wrdApp
    .Documents.Open (s)
    .Selection.MoveDown Count:=11 ' не пойму что это.
    .Selection.TypeText Text:="текст текст текст"
    .ActiveDocument.Save
    .Visible = True
    .Activate
  End With
End Sub

или так (вставиться содержимое ячейки A1):

Sub writeWORD()
  [A1].Copy
  s = ThisWorkbook.Path & "\doс.doc" ' по умолчанию файл Ворд в тоже папке. или поменяйте путь
  Dim wrdApp As Object: Set wrdApp = CreateObject("Word.Application")
  With wrdApp
    .Documents.Open (s)
    .Selection.PasteSpecial
    .ActiveDocument.Save
    .Visible = True
    .Activate
  End With
End Sub

[maksim_serg]

все работает, если убрать строчку

.Activate

а еще такой вопрос: как после открытия докумета word перейти на закладку в нем? использовал такой код:

Dim f As String
f = "файл"
    With CreateObject("word.application")
    Set x = ThisWorkbook.Sheets(1)
        .documents.Open (f)
        .Visible = True
        .Selection.Goto What:=wdGoToBookmark, Name:="по_строит_уч"
        .Selection.TypeText Text:=x.Range("K2").Value
    End With

Но word выдает ошибку: Данная закладка не существует. Тот же код в word'е работает без ошибок

[maksim_serg]

нашел ткой вариант:

.ActiveDocument.Bookmarks("по_строит_уч").Select
          .Selection.InsertAfter x.Range("K2").Value

[EducatedFool]

Но word выдает ошибку: Данная закладка не существует. Тот же код в word'е работает без ошибок

Может, потому, что Word знает, чему равна константа wdGoToBookmark, а ваш макрос - не знает?
(библиотека Word ведь не подключена к проекту, судя по тому, что используется позднее связывание)

нашел ткой вариант:

Можно так попробовать:

Sub test()
    Dim f As String
    f = "ПОЛНЫЙ ПУТЬ К ФАЙЛУ"
    Set x = ThisWorkbook.Sheets(1)
    With CreateObject("word.application")
        .Visible = True
        With .documents.Open(f)
            .Bookmarks("по_строит_уч").Range.Text = x.Range("K2")
            .Bookmarks("по_строит_уч2").Range.Text = x.Range("K3")
            .Bookmarks("по_строит_уч3").Range.Text = x.Range("K4")
            .Save    ' сохраняем документ
        End With
        .Quit ' закрываем Word
    End With
End Sub

[maksim_serg]

выдал ошибку: 438 - "Объект не поддерживает данный метод" (или что-то вроде этого - не знаю английского)

[EducatedFool]

Сообщение от maksim_serg

выдал ошибку: 438 - "Объект не поддерживает данный метод" (или что-то вроде этого - не знаю английского)

Не поленился, проверил - создав вордовский документ с одноимёнными закладками, - ВСЁ РАБОТАЕТ.
(WinXP, Office 2003)

Sub test()
    Dim f As String
    f = "C:\Documents and Settings\Admin\Рабочий стол\Документ Microsoft Word.doc"
    Set x = ThisWorkbook.Sheets(1)
    'Dim doc As Word.Document, WA As Word.Application ' если подключена библиотека word
    Set WA = CreateObject("word.application")
    With WA
        .Visible = True
        With .documents.Open(f)
            .Bookmarks("по_строит_уч").Range.Text = x.Range("K2")
            .Bookmarks("по_строит_уч2").Range.Text = x.Range("K3")
            .Bookmarks("по_строит_уч3").Range.Text = x.Range("K4")
            .Save    ' сохраняем документ
        End With
        .Quit ' закрываем Word
    End With
End Sub

Ошибка может появляться, если хотя бы одной из закладок нет в документе.

[maksim_serg]

и все таки выдает ошибку. или руки кривые.
буду пользоваться:

.ActiveDocument.Bookmarks("по_строит_уч").Select
.Selection.InsertAfter x.Range("K2").Value