Cравнить 2 списка на отличия

[Евгений Таб]

Добрый день уважаемые программисты,

Помогите советом/решением (если уже сталкивались с похожим),
как быстро сравнить 2 диапазона данных на НЕСОВПАДЕНИЯ.

Всего в обработке события должно участвовать 4 столбца. 2 на странице с данными и 2 на странице библиотекой.

Если данные по ключу NUMBER на вкладке DATA отличаются во вкладке CHECK, то вывести msgbox с перечисленными полями NUMBER где есть расхождения, если данные идентичны, то вывести msgbox OK.

Формулой через ВПР это легко реализуется, но очень хочется разобраться как сделать это одним кликом. Причем столбцы могут содержать пробелы...

Во вложении примерчик, пож-ста помогите с чего начать.
Спасибо!

[Aleksandr H.]

алгоритм

Цикл по столбцу Number
-проверяем результат сравнения Application.WorksheetFunctions.VLOO KUP(DATA.NUMBER,CHECK.CODE) с DATA.CODE
-- Не равно: (string)S <= data.number
Если len(string) != 0 - msgbox(s) иначе "ok"

[Евгений Таб]

Сообщение от Aleksandr H.

алгоритм

Свое понимание алгоритмов я оцениваю на твердую тройку В принципе я уже почти подошел к вашему ответу, дальше пока тяжело. Можете еще немного детализировать....

[Aleksandr H.]

Я так бы делал, наверное.

Function VPR(rngWhat As Range, rngWhere As Range)
    Dim numberWhat As String, codeWhat
    Dim numberWhere As String, codeWhere, colWhere As Long
    Dim r As Long, s As String
    s = ""
    For r = 1 To rngWhat.Rows.Count
        numberWhat = rngWhat.Cells(r, 1)
        codeWhat = rngWhat(r, rngWhat.Columns.Count)
        On Error Resume Next
        codeWhere = Application.WorksheetFunction.VLookup(numberWhat, rngWhere, rngWhere.Columns.Count, 0)
        If Err.Number = 0 Then
            If codeWhat <> codeWhere Then
                s = s & numberWhat & vbNewLine
            End If
        End If
        On Error GoTo 0
    Next r
    If s <> "" Then
        VPR = s
    Else
        VPR = "OK"
    End If
End Function

Sub test()
    MsgBox (VPR(Range("Data!C2:K18"), Range("CHECK!A2:B20")))
End Sub

Дебажте, рефактурируйте, ищите/ждите лучшие предложения.

[Евгений Таб]

Спасибо, за оч сложный пример )))) буду изучать/ждать решения попроще.... если конечно это можно сделать проще ))

[IgorGO]

или так:

Function VPR$(rngWhat As Range, rngWhere As Range)
    Dim c As Range
    For Each c In rngWhat
      If WorksheetFunction.CountIf(rngWhere, c) = 0 Then VPR = VPR & " " & c
    Next
    If VPR = "" Then VPR = "Ok"
End Function

Sub test()
    MsgBox (VPR(Range("Data!C2:C18"), Range("CHECK!A2:A9")))
End Sub

[Aleksandr H.]

Iгор, результат немного не тот что ТС хотел, но никто и не требовал его, только идею.

[Hugo121]

Проще использовать словарь и коллекцию для результатов.

Option Explicit

Sub tt()
    Dim a, b, i&, col As New Collection
    With Sheets("DATA")
        a = .[c1].CurrentRegion.Value
        b = .[c1].CurrentRegion.Offset(, 8).Value
    End With
    With CreateObject("scripting.dictionary"): .comparemode = 1
        For i = 2 To UBound(a): .Item(a(i, 1)) = b(i, 1): Next
        a = Sheets("CHECK").[a1].CurrentRegion.Value
        For i = 2 To UBound(a)
            If .Item(a(i, 1)) <> a(i, 2) Then col.Add a(i, 1)
        Next
    End With

    'вывод результат делайте как хотите
    Dim el
    For Each el In col
        MsgBox "Расхожение в ключе " & el
    Next

End Sub

[maria_ods]

Всем привет!!! Ребята, подскажите пожалуйста как в Exсel найти достоверную разницу между двумя столбиками чисел (диссер по психол.исследованию). Если можно языком простым и доступным))) Вся надежда на Вас! Заранее искренне благодарю откликнувшихся!!

[Aleksandr H.]

maria_ods, https://sites.google.com/site/umkmat...dstvami-excel-

http://uborshizzza.livejournal.com/67808.html