Добавить строку в таблицу с объединенными ячейками

[Stilet]

Всем доброго. Есть таблица, в которой шапка содержит объединенные ячейки.
Задача: Добавлять в цикле в таблицу строки и заполнять их ячейки данными.
Делаю такие манипуляции:

Private Sub AddRow(t As Table)
 Dim r As Row
 Set r = t.Rows.Add
 
 If Not r Is Nothing Then
  For i = 0 To adorec.Fields.Count - 1
   s = adorec.Fields(i).Value
   r.Cells(i + 1).Range.Text = s
  Next i
 End If
End Sub

Где t - передаваемая таблица как ThisDocument.Tables(1)
adorec - источник данных.

Проблема в том что переменная r принимает значение Nothing после t.Rows.Add
Самое непонятное для меня то что строки добавляются. Но обратится к ним я почему-то не могу.
Подскажите как решать такую проблему и почему она происходит?

P.S. Текст ошибки:

Отсутствует доступ к отдельным строкам, поскольку таблица имеет ячейки, объединенные по вертикали

[Казанский]

Если в таблице есть объединенные ячейки по вертикали, то строки как бы не существуют, т.к. в одной и той же строке ячейки имеют разный номер строки.
Аналогично, если в таблице есть объединенные ячейки по горизонтали, то столбцы как бы не существуют, т.к. в одном и том же столбце ячейки имеют разный номер столбца.
Если ячейки объединены только по вертикали, можно сделать так:

Private Sub AddRow(t As Table)
 Dim i&, s$, c As Cell
 t.Rows.Add
 With t.Columns(1)
    Set c = .Cells(.Cells.Count) 'последняя ячейка первого столбца
 End With
  For i = 0 To adorec.Fields.Count - 1
   s = adorec.Fields(i).Value
   c.Range.Text = s
   Set c = c.Next 'след. ячейка в строке
  Next i
 End Sub

Если есть объединение и по горизонтали, и по вертикали, то так можно получить последнюю ячейку в таблице

Set c = t.Range.Cells(t.Range.Cells.Count)

и плясать от нее.

[Ципихович Эндрю]

ну так и файл где пробуете и как начинаете код исполнять

[Stilet]

Казанский

Идею понял, спасибо.